rustconn-bin

MEDIUM

maintainer undefined 0 votes scanned 2026-10-24 09:40:04.174424

View on AUR

Why flagged

The package installs a prebuilt binary from a GitHub release without source code availability, creating an unverifiable supply-chain risk despite the project being on a trusted forge.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Medium AI review of an ambiguous pattern llm_review

The static rules found a suspicious pattern they could not resolve, so an AI model (qwen/qwen3-235b-a22b-2507) reviewed it and judged it MEDIUM (confidence 95%): The package installs a prebuilt binary from a GitHub release without source code availability, creating an unverifiable supply-chain risk despite the project being on a trusted forge.

PKGBUILD

      1# Maintainer: undefined-ux <undefined_1@outlook.com>
    
      2pkgname=rustconn-bin
    
      3pkgver=0.23.21
    
      4pkgrel=1
    
      5pkgdesc='Modern GTK4 connection manager for SSH, RDP, VNC and SPICE (prebuilt)'
    
      6arch=('x86_64')
    
      7url='https://github.com/totoshko88/RustConn'
    
      8license=('GPL-3.0-or-later')
    
      9depends=(
    
      10  'alsa-lib'
    
      11  'cairo'
    
      12  'dbus'
    
      13  'gcc-libs'
    
      14  'gdk-pixbuf2'
    
      15  'glib2'
    
      16  'glibc>=2.39'
    
      17  'graphene'
    
      18  'gtk4>=4.14'
    
      19  'libadwaita>=1.5'
    
      20  'openssh'
    
      21  'openssl>=3.0'
    
      22  'pango'
    
      23  'vte4>=0.76'
    
      24  'webkitgtk-6.0>=2.40'
    
      25  'which'
    
      26  'zlib'
    
      27)
    
      28checkdepends=('appstream' 'desktop-file-utils')
    
      29optdepends=(
    
      30  '1password-cli: 1Password credential storage'
    
      31  'aws-cli: AWS connections'
    
      32  'aws-session-manager-plugin: AWS SSM connections'
    
      33  'azure-cli: Azure connections'
    
      34  'bitwarden-cli: Bitwarden credential storage'
    
      35  'boundary: Boundary connections'
    
      36  'cloudflared: Cloudflare connections'
    
      37  'freerdp: External RDP client fallback'
    
      38  'google-cloud-cli: Google Cloud connections'
    
      39  'keepassxc: KeePassXC credential storage'
    
      40  'kubectl: Shell access to Kubernetes pods'
    
      41  'libappindicator: Display icon in system tray'
    
      42  'libsecret: secret-tool for importing credentials'
    
      43  'mc: SFTP via Midnight Commander FISH VFS'
    
      44  'mosh: MOSH connections'
    
      45  'oci-cli: Oracle Cloud connections'
    
      46  'openh264: H.264 decoding for embedded RDP'
    
      47  'pass: Password Store credential storage'
    
      48  'passbolt-cli: Passbolt credential storage'
    
      49  'picocom: Serial connections'
    
      50  'tailscale: Tailscale connections'
    
      51  'teleport: Teleport connections'
    
      52  'tigervnc: External VNC client fallback'
    
      53  'virt-viewer: External SPICE client'
    
      54  'waypipe: Wayland application forwarding over SSH'
    
      55)
    
      56provides=("rustconn=$pkgver")
    
      57conflicts=('rustconn' 'rustconn-appimage')
    
      58options=('!strip' '!debug')
    
      59
    
      60_app_id=io.github.totoshko88.RustConn
    
      61_deb="rustconn_${pkgver}_amd64.deb"
    
      62source=(
    
      63  "$url/releases/download/v$pkgver/$_deb"
    
      64  "${_app_id}-rdp.xml"
    
      65  "${_app_id}-vv.xml"
    
      66)
    
      67noextract=("$_deb")
    
      68sha256sums=(
    
      69  '3ad913d082eda9737a56a8c65a4cace8d13708fb28b29c8fe5cbdd93d39f6357'
    
      70  '6752641f8272fae15901cc4de4052514e846821fbeba797baa8d81850d508cda'
    
      71  'e833e539337e3a348f21a6757f015bfc7994df0789771880550350f0d04c45f0'
    
      72)
    
      73
    
      74prepare() {
    
      75  bsdtar -xf "$_deb" data.tar.zst
    
      76  mkdir -p deb-root
    
      77  bsdtar -xf data.tar.zst -C deb-root
    
      78}
    
      79
    
      80check() {
    
      81  desktop-file-validate "deb-root/usr/share/applications/${_app_id}.desktop"
    
      82  appstreamcli validate --no-net "deb-root/usr/share/metainfo/${_app_id}.metainfo.xml"
    
      83  deb-root/usr/bin/rustconn --version
    
      84  deb-root/usr/bin/rustconn-cli --version
    
      85}
    
      86
    
      87package() {
    
      88  cp -a --no-preserve=ownership deb-root/usr "$pkgdir/"
    
      89  mv "$pkgdir/usr/share/doc/rustconn" "$pkgdir/usr/share/doc/$pkgname"
    
      90
    
      91  # The upstream deb omits these MIME definitions from its source tree.
    
      92  install -Dm644 "${_app_id}-rdp.xml" "${_app_id}-vv.xml" \
    
      93    -t "$pkgdir/usr/share/mime/packages/"
    
      94}
    
      95

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-24 09:40:04	Medium	2