salam-bin

LOW

maintainer basemax 0 votes scanned 2026-09-24 01:41:16.165362

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Seyyed Ali Mohammadiyeh (Max Base) <MaxBaseCode@gmail.com>
    
      2# shellcheck shell=bash disable=SC2034,SC2154,SC2164
    
      3
    
      4pkgname=salam-bin
    
      5_pkgname=salam
    
      6pkgver=0.4.3
    
      7pkgrel=1
    
      8pkgdesc="General-purpose systems programming language with a built-in DSL (prebuilt binary)"
    
      9arch=('x86_64' 'aarch64' 'armv7h')
    
      10url="https://github.com/SalamLang/Salam"
    
      11license=('GPL-3.0-or-later')
    
      12provides=("salam=${pkgver}")
    
      13conflicts=('salam')
    
      14options=('!strip' '!debug')
    
      15
    
      16_url="${url}/releases/download/v${pkgver}"
    
      17source_x86_64=("${pkgname}-${pkgver}-x86_64.tar.gz::${_url}/salam-${pkgver}-linux-x86_64.tar.gz")
    
      18source_aarch64=("${pkgname}-${pkgver}-aarch64.tar.gz::${_url}/salam-${pkgver}-linux-aarch64.tar.gz")
    
      19source_armv7h=("${pkgname}-${pkgver}-armv7h.tar.gz::${_url}/salam-${pkgver}-linux-armhf.tar.gz")
    
      20sha256sums_x86_64=('72e312aa4e8ad71ad51d0fe002e743756b34c506b3646de5bc928cae962c0e0b')
    
      21sha256sums_aarch64=('0c7ff6edd2d848b66ac72aa43a0d5f45455411a9f90d1c87312e0fb1613ef111')
    
      22sha256sums_armv7h=('884ff3ba5a3bdc62d0fc33d68b9229afa685ab41d9dff1eb3969e53324afea53')
    
      23
    
      24_srcdir() {
    
      25    case "$CARCH" in
    
      26        x86_64)  echo "salam-linux-x86_64" ;;
    
      27        aarch64) echo "salam-linux-aarch64" ;;
    
      28        armv7h)  echo "salam-linux-armhf" ;;
    
      29    esac
    
      30}
    
      31
    
      32package() {
    
      33    local d
    
      34    d="$(_srcdir)"
    
      35    cd "${srcdir}/${d}"
    
      36
    
      37    # The compiler resolves std/ relative to its own binary, so the two stay
    
      38    # together under /usr/lib and /usr/bin/salam is a wrapper.
    
      39    install -Dm755 salam "${pkgdir}/usr/lib/${_pkgname}/salam"
    
      40
    
      41    install -dm755 "${pkgdir}/usr/lib/${_pkgname}/std"
    
      42    cp -a std/. "${pkgdir}/usr/lib/${_pkgname}/std/"
    
      43    find "${pkgdir}/usr/lib/${_pkgname}/std" -type d -exec chmod 755 {} +
    
      44    find "${pkgdir}/usr/lib/${_pkgname}/std" -type f -exec chmod 644 {} +
    
      45
    
      46    if [ -d sysroots ]; then
    
      47        cp -a sysroots "${pkgdir}/usr/lib/${_pkgname}/sysroots"
    
      48    fi
    
      49
    
      50    install -dm755 "${pkgdir}/usr/bin"
    
      51    cat > "${pkgdir}/usr/bin/${_pkgname}" <<'EOF'
    
      52#!/bin/sh
    
      53SALAM_HOME=/usr/lib/salam
    
      54export SALAM_STD="${SALAM_STD:-$SALAM_HOME/std}"
    
      55exec "$SALAM_HOME/salam" "$@"
    
      56EOF
    
      57    chmod 755 "${pkgdir}/usr/bin/${_pkgname}"
    
      58
    
      59    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      60    if [ -f README.md ]; then
    
      61        install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      62    fi
    
      63}
    
      64

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-24 01:41:16	Low	1