scarletnx-git

LOW

maintainer fuddlesworth 0 votes scanned 2026-10-28 17:50:30.107060

View on AUR

Why flagged

The package builds from a public Git repository with SKIP'd checksum, but sources are transparent and build-time dependencies are pinned and verified; no remote code execution or obfuscation is present.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from a public Git repository with SKIP'd checksum, but sources are transparent and build-time dependencies are pinned and verified; no remote code execution or obfuscation is present.

PKGBUILD

      1# Maintainer: fuddlesworth <fuddlesworth at users dot noreply dot github dot com>
    
      2#
    
      3# Built from main. The build fetches its pinned libraries (FFmpeg, OpenSSL, Vulkan-Headers, volk, VMA, hactool and
    
      4# the rest of cmake/dependencies.cmake) with CPM at configure time, each checked by SHA-256.
    
      5
    
      6pkgname=scarletnx-git
    
      7pkgver=r2548.d42b41d
    
      8pkgrel=1
    
      9pkgdesc='Static recompiler that turns ARM64 and ARM32 programs into native code, like FEX-Emu in reverse'
    
      10arch=('x86_64' 'aarch64')
    
      11url='https://github.com/scarletnx/ScarletNX'
    
      12# ScarletNX, the AGB board (MPL-2.0), and what links into it statically: FFmpeg (LGPL), OpenSSL, hactool, lz4, zstd,
    
      13# enet, volk, VMA, lunasvg and plutovg. The shared fonts' stand-ins are OFL-1.1
    
      14license=(
    
      15    'GPL-3.0-or-later'
    
      16    'Apache-2.0'
    
      17    'BSD-2-Clause'
    
      18    'BSD-3-Clause'
    
      19    'FTL'
    
      20    'ISC'
    
      21    'LGPL-2.1-or-later'
    
      22    'MIT'
    
      23    'MPL-2.0'
    
      24    'OFL-1.1'
    
      25)
    
      26depends=(
    
      27    'glibc'
    
      28    'libgcc'
    
      29    'libstdc++'
    
      30    'hicolor-icon-theme'
    
      31    'llvm-libs'
    
      32    'sdl3'
    
      33    'vulkan-driver'
    
      34    'vulkan-icd-loader'
    
      35)
    
      36makedepends=(
    
      37    'clang'
    
      38    'cmake'
    
      39    'git'
    
      40    'llvm'
    
      41    'nasm'
    
      42    'ninja'
    
      43    'perl'
    
      44    'pkgconf'
    
      45    'python'
    
      46)
    
      47# glslang's release has prebuilt tools only for x86-64 (cmake/glsl.cmake), elsewhere the build takes the system's
    
      48makedepends_aarch64=('glslang')
    
      49provides=('scarletnx')
    
      50conflicts=('scarletnx')
    
      51# The build checks its own compiler flags (cmake/banned_flags.cmake), and the LTO flags of makepkg are GCC's
    
      52options=('!lto')
    
      53source=('git+https://github.com/scarletnx/ScarletNX.git')
    
      54sha256sums=('SKIP')
    
      55
    
      56pkgver() {
    
      57    cd ScarletNX
    
      58    # The only tag is "nightly", which moves: count the commits instead
    
      59    printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      60}
    
      61
    
      62build() {
    
      63    # SNX_DEPLOY off: a build of the runtime otherwise copies it next to each game in the data folder of $HOME
    
      64    CC=clang CXX=clang++ cmake -S ScarletNX -B build -G Ninja \
    
      65        -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    
      66        -DCMAKE_INSTALL_PREFIX=/usr \
    
      67        -DSNX_DEPLOY=OFF \
    
      68        -DSNX_TRACY=OFF \
    
      69        -DBUILD_TESTING=OFF \
    
      70        -Wno-dev
    
      71    cmake --build build
    
      72}
    
      73
    
      74package() {
    
      75    DESTDIR="$pkgdir" cmake --install build
    
      76    # Seat access to the pads' event nodes and to the hidraw nodes of the console's controllers (docs/USAGE.md)
    
      77    install -Dm644 ScarletNX/dist/72-scarletnx-input.rules "$pkgdir/usr/lib/udev/rules.d/72-scarletnx-input.rules"
    
      78}
    
      79

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-28 17:50:30	Low	2