scottbass3-clipd-git

LOW

maintainer Scottbass 0 votes scanned 2026-10-17 00:21:55.226236

View on AUR

Why flagged

Package builds from source via git, uses SKIP for checksum which is common for git sources, and installs only binaries and docs from the project's own repository; no remote code execution or untrusted prebuilt binaries.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): Package builds from source via git, uses SKIP for checksum which is common for git sources, and installs only binaries and docs from the project's own repository; no remote code execution or untrusted prebuilt binaries.

PKGBUILD

      1# Maintainer: scottbass3 <valentin dot carroy at hotmail dot fr>
    
      2
    
      3pkgname=scottbass3-clipd-git
    
      4_name=clipd
    
      5pkgver=r9.b5b6a4f
    
      6pkgrel=1
    
      7pkgdesc="Clipboard history daemon for Wayland, with pins organized in categories"
    
      8arch=('x86_64' 'aarch64')
    
      9url="https://github.com/scottbass3/clipd"
    
      10license=('GPL-3.0-or-later')
    
      11depends=('glibc' 'libgcc')
    
      12makedepends=('git' 'cargo')
    
      13provides=('clipd')
    
      14conflicts=('clipd')
    
      15source=("$_name::git+$url.git")
    
      16sha256sums=('SKIP')
    
      17# The bundled SQLite would be built as GCC LTO bitcode, which rustc cannot link.
    
      18options=('!lto')
    
      19
    
      20pkgver() {
    
      21  cd "$_name"
    
      22  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      23}
    
      24
    
      25prepare() {
    
      26  cd "$_name"
    
      27  export RUSTUP_TOOLCHAIN=stable
    
      28  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      29}
    
      30
    
      31build() {
    
      32  cd "$_name"
    
      33  export RUSTUP_TOOLCHAIN=stable
    
      34  export CARGO_TARGET_DIR=target
    
      35  cargo build --frozen --release
    
      36}
    
      37
    
      38check() {
    
      39  cd "$_name"
    
      40  export RUSTUP_TOOLCHAIN=stable
    
      41  cargo test --frozen
    
      42}
    
      43
    
      44package() {
    
      45  cd "$_name"
    
      46  install -Dm755 target/release/clipd -t "$pkgdir/usr/bin/"
    
      47  install -Dm644 contrib/clipd.service -t "$pkgdir/usr/lib/systemd/user/"
    
      48  install -Dm644 README.md -t "$pkgdir/usr/share/doc/$_name/"
    
      49}
    
      50

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-17 00:21:55	Low	2
2026-10-16 00:12:47	Low	2
2026-10-15 00:28:05	Low	2
2026-10-14 09:19:50	Low	2