shiftpaper-git

LOW

maintainer cpritch 0 votes scanned 2026-10-06 12:02:18.455551

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Charles Pritchard <charlespritchard.work@gmail.com>
    
      2pkgname=shiftpaper-git
    
      3pkgver=0.4.0.r0.g44334ee
    
      4pkgrel=1
    
      5pkgdesc="Parallax wallpaper daemon for Wayland with monocular depth estimation"
    
      6arch=('x86_64')
    
      7url="https://github.com/CPritch/shiftpaper"
    
      8license=('MIT')
    
      9depends=('wayland' 'vulkan-icd-loader' 'onnxruntime')
    
      10makedepends=('cargo' 'git')
    
      11optdepends=('onnxruntime-cuda: bake wallpapers on an NVIDIA GPU')
    
      12provides=("${pkgname%-git}")
    
      13conflicts=("${pkgname%-git}")
    
      14options=('!lto')
    
      15source=("$pkgname::git+https://github.com/CPritch/shiftpaper.git")
    
      16sha256sums=('SKIP')
    
      17
    
      18pkgver() {
    
      19	cd "$pkgname"
    
      20	git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      21}
    
      22
    
      23prepare() {
    
      24	cd "$pkgname"
    
      25	export RUSTUP_TOOLCHAIN=stable
    
      26	cargo fetch --locked --target "$(rustc --print host-tuple)"
    
      27}
    
      28
    
      29build() {
    
      30	cd "$pkgname"
    
      31	export RUSTUP_TOOLCHAIN=stable
    
      32	export CARGO_TARGET_DIR=target
    
      33	# load-dynamic uses the system onnxruntime instead of downloading one.
    
      34	cargo build --frozen --release --package shiftpaper-cli \
    
      35		--no-default-features --features load-dynamic
    
      36	cargo build --frozen --release --package shiftpaper-daemon
    
      37}
    
      38
    
      39check() {
    
      40	cd "$pkgname"
    
      41	export RUSTUP_TOOLCHAIN=stable
    
      42	export CARGO_TARGET_DIR=target
    
      43	cargo test --frozen --release --package shiftpaper-config --package shiftpaper-daemon
    
      44	cargo test --frozen --release --package shiftpaper-cli \
    
      45		--no-default-features --features load-dynamic
    
      46}
    
      47
    
      48package() {
    
      49	cd "$pkgname"
    
      50	install -Dm755 target/release/shiftpaper "$pkgdir/usr/bin/shiftpaper"
    
      51	install -Dm755 target/release/shiftpaperd "$pkgdir/usr/bin/shiftpaperd"
    
      52	install -Dm644 shiftpaperd.service "$pkgdir/usr/lib/systemd/user/shiftpaperd.service"
    
      53	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      54	install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    
      55	install -Dm644 assets/icon/hicolor/scalable/apps/shiftpaper.svg \
    
      56		"$pkgdir/usr/share/icons/hicolor/scalable/apps/shiftpaper.svg"
    
      57	install -Dm644 assets/icon/hicolor/symbolic/apps/shiftpaper-symbolic.svg \
    
      58		"$pkgdir/usr/share/icons/hicolor/symbolic/apps/shiftpaper-symbolic.svg"
    
      59}
    
      60

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-06 12:02:18	Low	1
2026-10-06 00:13:36	Clean	2
2026-10-05 23:40:58	Low	1