slant-git

LOW
maintainer aperez 0 votes scanned 2026-09-17 00:27:14.276658
View on AUR
Why flagged

The package builds from source code hosted on official and project-owned domains (github.com, kristaps.bsd.lv, ftp.openbsd.org, sqlite.org); the non-whitelisted hosts are legitimate project infrastructure, and all downloaded sources are compiled locally without executing untrusted binaries.

Triggered rules

Low AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-07-25) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The package builds from source code hosted on official and project-owned domains (github.com, kristaps.bsd.lv, ftp.openbsd.org, sqlite.org); the non-whitelisted hosts are legitimate project infrastructure, and all downloaded sources are compiled locally without executing untrusted binaries.

1 higher static finding superseded - not the current verdict (shown for transparency)
Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

  • PKGBUILD:14 "http://ftp.openbsd.org/pub/OpenBSD/LibreSSL/libressl-${_libressl_ver}.tar.gz"
  • PKGBUILD:16 "https://www.sqlite.org/2019/sqlite-amalgamation-${_sqlite3_ver}.zip")

PKGBUILD

2 offending line(s) highlighted
1# Maintainer: Adrian Perez de Castro <aperez@igalia.com>
2_libressl_ver='2.8.3'
3_sqlite3_ver='3270100'
4pkgname=slant-git
5pkgver=0.0.17.r10.gc3d1f0b
6pkgrel=1
7pkgdesc='Minimal open source system monitor for remote UNIX machines'
8url=https://kristaps.bsd.lv/slant
9license=(custom:ISC)
10arch=(x86_64)
11makedepends=(kwebapp kcgi ksql git)
12depends=(zlib sh)
13source=("${pkgname}::git+https://github.com/kristapsdz/${pkgname%-git}/"
14 "http://ftp.openbsd.org/pub/OpenBSD/LibreSSL/libressl-${_libressl_ver}.tar.gz"
15 "http://ftp.openbsd.org/pub/OpenBSD/LibreSSL/libressl-${_libressl_ver}.tar.gz.asc"
16 "https://www.sqlite.org/2019/sqlite-amalgamation-${_sqlite3_ver}.zip")
17sha512sums=('SKIP'
18 '3967e08b3dc2277bf77057ea1f11148df7f96a2203cd21cf841902f2a1ec11320384a001d01fa58154d35612f7981bf89d5b1a60a2387713d5657677f76cc682'
19 'SKIP'
20 '9e9ace498bfb89631d3798e43d3da372d204b869948ecd77fbf18a7eee2b364cdbc6d20fc0482457506a5301bb492fec3af9bf87d4d9f047e08181b7e74aeb68')
21validpgpkeys=(A1EB079B8D3EB92B4EBD3139663AF51BD5E4D8D5)
22
23pkgver () {
24 cd "${pkgname}"
25 ( set -o pipefail
26 git describe --long --tags 2> /dev/null\
27 | sed -e 's/^VERSION_//;s/\([^-]*-g\)/r\1/;s/-/./g;s/_/./g' ||
28 printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
29 )
30}
31
32build () {
33 # SQLite3
34 msg2 "Building static SQLite3 ${_sqlite3_ver} ..."
35 cd "${srcdir}/sqlite-amalgamation-${_sqlite3_ver}"
36 gcc ${CFLAGS} \
37 -DSTDC_HEADERS=1 -DHAVE_SYS_TYPES_H=1 -DHAVE_SYS_STAT_H=1 \
38 -DHAVE_STDLIB_H=1 -DHAVE_STRING_H=1 -DHAVE_MEMORY_H=1 \
39 -DHAVE_STRINGS_H=1 -DDHAVE_INTTYPES_H=1 -DHAVE_STDINT_H=1 \
40 -DHAVE_UNISTD_H=1 -DHAVE_FDATASYNC=1 -DHAVE_USLEEP=1 \
41 -DHAVE_LOCALTIME_R=1 -DHAVE_GMTIME_R=1 -DHAVE_DECL_STRERROR_R=1 \
42 -DHAVE_STRERROR_R=1 -DHAVE_POSIX_FALLOCATE=1 -DHAVE_ZLIB_H=1 \
43 -D_REENTRANT=1 -DSQLITE_THREADSAFE=1 -DSQLITE_ENABLE_FTS{4,5} \
44 -DSQLITE_ENABLE_JSON1 -DSQLITE_ENABLE_RTREE \
45 -DSQLITE_ENABLE_SESSION -DSQLITE_OMIT_LOAD_EXTENSION \
46 -DSQLITE_ENABLE_PREUPDATE_HOOK -DSQLITE_HAVE_ZLIB \
47 -c -o sqlite3.o sqlite3.c
48 ar rcs libsqlite3.a sqlite3.o
49
50 # LibreSSL
51 msg2 "Building static LibreSSL ${_libressl_ver} ..."
52 cd "${srcdir}/libressl-${_libressl_ver}"
53 ./configure \
54 --disable-shared \
55 --enable-static \
56 --prefix=/usr \
57 --sysconfdir=/etc
58 make install DESTDIR="$(pwd)/prefix"
59
60 # Slant
61 msg2 "Building Slant ${pkgver} ..."
62 cd "${srcdir}/${pkgname}"
63 ./configure PREFIX=/usr MANDIR=/usr/share/man SBINDIR=/usr/bin
64
65 # Workaround things to make sure that binaries are linked to the
66 # static versions of LibreSSL and SQLite3 built above. This is
67 # ugly, but gets the job done.
68 cat >> Makefile.configure <<-EOF
69 XCFLAGS := \$(CFLAGS)
70 XCFLAGS += ${CFLAGS} -fPIC -fPIE -s
71 XCFLAGS += -I${srcdir}/libressl-${_libressl_ver}/prefix/usr/include
72 XCFLAGS += -I${srcdir}/sqlite-amalgamation-${_sqlite3_ver}
73 XCFLAGS += \$(shell pkg-config libtls libssl libcrypto --cflags) -pthread
74
75 XLDFLAGS := \$(LDFLAGS)
76 XLDFLAGS += ${LDFLAGS} -fPIE -s
77 XLDFLAGS += -L${srcdir}/libressl-${_libressl_ver}/prefix/usr/lib
78 XLDFLAGS += -L${srcdir}/sqlite-amalgamation-${_sqlite3_ver}
79
80 XLDADD := \$(LDADD)
81 XLDADD += \$(shell pkg-config libtls libssl libcrypto --libs) -lm -lresolv -pthread
82
83 override LDADD = \$(XLDADD)
84 override LDFLAGS = \$(XLDFLAGS)
85 override CFLAGS = \$(XCFLAGS)
86
87 override LDADD_SLANT_COLLECTD = \$(XLDADD)
88 override LDADD_SLANT_CGI = \$(XLDADD)
89 override LDADD_SLANT = \$(XLDADD)
90 EOF
91
92 PKG_CONFIG_PATH="${srcdir}/libressl-${_libressl_ver}/prefix/usr/lib/pkgconfig" \
93 make
94}
95
96package () {
97 cd "${pkgname}"
98
99 # Ugh. Workaround.
100 install -dm755 "${pkgdir}/usr/share/man"/man{1,8}
101
102 PKG_CONFIG_PATH="${srcdir}/libressl-${_libressl_ver}/prefix/usr/lib/pkgconfig" \
103 make install \
104 DESTDIR="${pkgdir}" \
105 PREFIX=/usr \
106 SBINDIR=/usr/bin \
107 MANDIR=/usr/share/man \
108 CGIBIN=/usr/lib/slant
109}
110

Scan history

Scanned at (UTC)SeverityRules
2026-09-17 00:27:14 Low 2
2026-09-16 00:03:17 Low 2
2026-09-15 00:25:31 Low 2
2026-09-14 00:27:57 Low 2
2026-09-13 00:19:54 Low 2
2026-09-12 00:25:17 Low 2
2026-09-11 00:19:22 Low 2
2026-09-10 00:22:44 Low 2
2026-09-09 00:04:09 Low 2
2026-09-08 00:18:08 Low 2
2026-09-07 00:30:15 Low 2
2026-09-06 00:17:06 Low 2
2026-09-05 00:16:27 Low 2
2026-09-04 00:03:13 Low 2
2026-09-03 00:15:47 Low 2
2026-09-02 00:02:31 Low 2
2026-09-01 00:11:19 Low 2
2026-08-31 00:19:57 Low 2
2026-08-30 00:04:14 Low 2
2026-08-29 00:29:17 Low 2

Report a package

Reports go to the AURWatch maintainer (one person) and are read by hand. No login required.

0 / 4000
Your suggestion