snmpb

maintainer nikost74 · 1 votes · scanned 2026-08-03 00:08:14.047287

LOW

Why flagged The package builds from source using official project repositories and release tarballs; the non-standard hosts are project-affiliated (e.g., TU Braunschweig, SourceForge) and the sources are not executed remotely, posing minimal supply-chain risk.

Triggered rules

LOW AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-07-25) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The package builds from source using official project repositories and release tarballs; the non-standard hosts are project-affiliated (e.g., TU Braunschweig, SourceForge) and the sources are not executed remotely, posing minimal supply-chain risk.

1 higher static finding superseded - not the current verdict (shown for transparency)

MEDIUM source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:30 "${pkgname}-code::git+https://git.code.sf.net/p/snmpb/code"
PKGBUILD:31 "https://www.ibr.cs.tu-bs.de/projects/libsmi/download/libsmi-${_smi}.tar.gz"

PKGBUILD

2 offending line(s) highlighted

      1# Maintainer: Nikos Toutountzoglou <nikos.toutou@protonmail.com>
    
      2
    
      3pkgname=snmpb
    
      4pkgver=1.0
    
      5pkgrel=11
    
      6pkgdesc="SNMP browser and MIB editor written in Qt"
    
      7arch=('x86_64')
    
      8url="https://sourceforge.net/projects/snmpb"
    
      9license=('GPL-2.0-only')
    
      10depends=(
    
      11  'gcc-libs'
    
      12  'glibc'
    
      13  'hicolor-icon-theme'
    
      14  'libglvnd'
    
      15  'qt5-base'
    
      16  'qwt'
    
      17)
    
      18makedepends=(
    
      19  'autoconf'
    
      20  'automake'
    
      21  'bison'
    
      22  'flex'
    
      23  'git'
    
      24  'qt5-tools'
    
      25)
    
      26_smi=0.5.0
    
      27_tomcrypt=1.18.2
    
      28_qwt=6.3.0
    
      29source=(
    
      30  "${pkgname}-code::git+https://git.code.sf.net/p/snmpb/code"
    
      31  "https://www.ibr.cs.tu-bs.de/projects/libsmi/download/libsmi-${_smi}.tar.gz"
    
      32  "https://github.com/libtom/libtomcrypt/releases/download/v${_tomcrypt}/crypt-${_tomcrypt}.tar.xz"
    
      33  "https://sourceforge.net/projects/qwt/files/qwt/${_qwt}/qwt-${_qwt}.tar.bz2"
    
      34  "0001-Fix-build-failure-with-gcc-15.patch"
    
      35)
    
      36sha256sums=('SKIP'
    
      37            'f21accdadb1bb328ea3f8a13fc34d715baac6e2db66065898346322c725754d3'
    
      38            '96ad4c3b8336050993c5bc2cf6c057484f2b0f9f763448151567fbab5e767b84'
    
      39            'dcb085896c28aaec5518cbc08c0ee2b4e60ada7ac929d82639f6189851a6129a'
    
      40            '7afa41f292e404854953ea52dac269671462cb638a6daf5cc21b5baaf92df7c5')
    
      41
    
      42prepare() {
    
      43  cd "${srcdir}"
    
      44  mv "libsmi-${_smi}" "libsmi"
    
      45  mv "libtomcrypt-${_tomcrypt}" "libtomcrypt"
    
      46  mv "qwt-${_qwt}" "qwt"
    
      47
    
      48  # Copy code to working directory
    
      49  mkdir -p "${pkgname}-${pkgver}"
    
      50  cp -Pr "${pkgname}-code"/{app,snmp++,license.txt,Makefile} "${pkgname}-${pkgver}/"
    
      51  cp -Pr libsmi libtomcrypt qwt "${pkgname}-${pkgver}/"
    
      52
    
      53  # Apply GCC 15 patch to libsmi
    
      54  patch -d "${pkgname}-${pkgver}/libsmi" -p1 < "${srcdir}/0001-Fix-build-failure-with-gcc-15.patch"
    
      55
    
      56  # Fix Qwt includes in app sources
    
      57  sed '30i#include <qwt_scale_widget.h>' -i "${pkgname}-${pkgver}/app/graph.cpp"
    
      58  sed '31i#include <qwt_scale_widget.h>' -i "${pkgname}-${pkgver}/app/graph.h"
    
      59
    
      60  # Patch qwt config for proper install locations
    
      61  sed -e '/^\s*QWT_INSTALL_PREFIX/ s|=.*|= /usr|' \
    
      62      -e '/^QWT_INSTALL_DOCS/ s|/doc|/share/doc/qwt|' \
    
      63      -e '/^QWT_INSTALL_HEADERS/ s|include|&/qwt|' \
    
      64      -e '/^QWT_INSTALL_PLUGINS/ s|plugins/designer|lib/qt/&|' \
    
      65      -e '/^QWT_INSTALL_FEATURES/ s|features|lib/qt/mkspecs/&|' \
    
      66      -i "${pkgname}-${pkgver}/qwt/qwtconfig.pri"
    
      67}
    
      68
    
      69build() {
    
      70  local build_dir="${pkgname}-${pkgver}"
    
      71  cd "${build_dir}"
    
      72
    
      73  export CFLAGS="${CFLAGS} -Wno-error=implicit-function-declaration"
    
      74
    
      75  # Build libsmi
    
      76  cd libsmi
    
      77  autoreconf -i
    
      78  ./configure \
    
      79    --disable-shared \
    
      80    --disable-yang \
    
      81    --with-pathseparator=";" \
    
      82    --with-dirseparator="/" \
    
      83    --with-smipath="/usr/share/apps/snmpb/mibs;/usr/share/apps/snmpb/pibs"
    
      84  make
    
      85  cd ..
    
      86
    
      87  # Build libtomcrypt
    
      88  cd libtomcrypt
    
      89  make library
    
      90  cd ..
    
      91
    
      92  # Build Qwt
    
      93  cd qwt
    
      94  qmake qwt.pro
    
      95  make
    
      96  cd ..
    
      97
    
      98  # Build main app
    
      99  cd app
    
      100  qmake -o makefile.snmpb snmpb.pro
    
      101  make -f makefile.snmpb
    
      102}
    
      103
    
      104package() {
    
      105  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/license.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      106  cd "${pkgname}-${pkgver}"
    
      107
    
      108  # Install the built package
    
      109  make INSTALL_PREFIX="${pkgdir}/usr" install
    
      110
    
      111  # Remove setuid/setgid if set
    
      112  chmod u-s,g-s "${pkgdir}/usr/bin/snmpb"
    
      113
    
      114  # User config files stored in
    
      115  # $HOME/.config/snmpb.sourceforge.net
    
      116
    
      117  # Default dirs for MIBs/PIBs
    
      118  # /usr/share/apps/snmpb/mibs
    
      119  # /usr/share/apps/snmpb/pibs
    
      120}
    
      121
    
      122# vim: ts=2 sw=2 et:
    
      123

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-03 00:08:14	LOW	2
2026-08-02 00:16:08	LOW	2
2026-08-01 00:11:18	LOW	2
2026-07-31 00:14:10	LOW	2
2026-07-30 00:17:23	LOW	2
2026-07-29 00:25:53	LOW	2
2026-07-28 00:07:28	LOW	2
2026-07-27 00:24:32	LOW	2
2026-07-26 00:07:32	LOW	2
2026-07-25 00:13:44	LOW	2
2026-07-24 00:02:28	LOW	2
2026-07-23 00:14:47	LOW	2
2026-07-22 00:29:32	LOW	2
2026-07-21 00:24:15	LOW	2
2026-07-20 00:19:49	LOW	2
2026-07-19 00:17:08	LOW	2
2026-07-18 00:14:48	LOW	2
2026-07-17 00:06:16	LOW	2
2026-07-16 00:05:41	LOW	2
2026-07-15 00:09:25	LOW	2