spiral-file-manager

LOW

maintainer sachesi 0 votes scanned 2026-09-18 17:28:51.851564

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: sachesi <xsachesi@pm.me>
    
      2
    
      3# pkgver and sha256sums are filled in by .github/workflows/aur.yml for each release.
    
      4pkgname=spiral-file-manager
    
      5_name=spiral
    
      6pkgver=0.17.0
    
      7pkgrel=1
    
      8pkgdesc='File manager for Wayland with a file chooser portal backend'
    
      9arch=('x86_64' 'aarch64')
    
      10url='https://github.com/sachesi/spiral'
    
      11license=('GPL-3.0-or-later')
    
      12depends=('gtk4>=1:4.22' 'libadwaita>=1:1.9' 'gtksourceview5' 'glib2' 'libseccomp'
    
      13         'gstreamer' 'gst-plugins-base-libs' 'gst-plugins-base' 'gst-plugin-gtk4'
    
      14         'bubblewrap' 'xdg-desktop-portal' 'hicolor-icon-theme' 'libgcc' 'glibc')
    
      15makedepends=('cargo' 'blueprint-compiler' 'just' 'gettext')
    
      16optdepends=('glycin: decode pictures in glycin'\''s sandbox'
    
      17            'gst-plugins-good: play common video and sound formats'
    
      18            'gst-plugins-bad: play more video and sound formats'
    
      19            'gst-libav: play most other video and sound formats'
    
      20            'gvfs: network locations, the Trash folder and remembered folder views'
    
      21            'gvfs-smb: Windows shares'
    
      22            'gvfs-nfs: NFS shares'
    
      23            'poppler: PDF previews'
    
      24            '7zip: 7z archives'
    
      25            'unrar: RAR archives'
    
      26            'xdg-terminal-exec: Open in Terminal'
    
      27            'gnome-disk-utility: open drives in Disks')
    
      28conflicts=('spiral-git')
    
      29source=("$_name-$pkgver.tar.gz::$url/archive/v$pkgver/$_name-$pkgver.tar.gz")
    
      30sha256sums=('451dec0d15e87e7c1713dc589b5de40237f41a3cdcfc5711e4cd3faae1475d9e')
    
      31
    
      32prepare() {
    
      33  cd "$_name-$pkgver"
    
      34  export RUSTUP_TOOLCHAIN=stable
    
      35  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      36}
    
      37
    
      38build() {
    
      39  cd "$_name-$pkgver"
    
      40  export RUSTUP_TOOLCHAIN=stable
    
      41  export CARGO_TARGET_DIR=target
    
      42  export SPIRAL_LIBEXECDIR=/usr/lib/$_name
    
      43  export SPIRAL_LOCALEDIR=/usr/share/locale
    
      44  cargo build --frozen --release
    
      45}
    
      46
    
      47check() {
    
      48  cd "$_name-$pkgver"
    
      49  export RUSTUP_TOOLCHAIN=stable
    
      50  export CARGO_TARGET_DIR=target
    
      51  cargo test --frozen
    
      52}
    
      53
    
      54package() {
    
      55  cd "$_name-$pkgver"
    
      56  DESTDIR="$pkgdir" just prefix=/usr install
    
      57  # Arch keeps helpers in /usr/lib/<name>; this works with every release's justfile.
    
      58  install -d "$pkgdir/usr/lib/$_name"
    
      59  mv "$pkgdir"/usr/libexec/* "$pkgdir/usr/lib/$_name/"
    
      60  rmdir "$pkgdir/usr/libexec"
    
      61  sed -i "s|/usr/libexec/|/usr/lib/$_name/|" \
    
      62    "$pkgdir/usr/share/dbus-1/services/org.freedesktop.impl.portal.desktop.spiral.service" \
    
      63    "$pkgdir/usr/share/applications/xdg-desktop-portal-spiral.desktop"
    
      64  # Releases up to 0.17.0 build the caches even in a staged install; pacman's hooks own them.
    
      65  rm -f "$pkgdir/usr/share/glib-2.0/schemas/gschemas.compiled" \
    
      66    "$pkgdir/usr/share/applications/mimeinfo.cache" \
    
      67    "$pkgdir/usr/share/icons/hicolor/icon-theme.cache"
    
      68}
    
      69

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-18 17:28:51	Low	1