squoosh-desktop

LOW

maintainer huntergunter89 1 votes scanned 2026-09-25 11:11:47.608437

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: huntergunter89 <huntergunter89@gmail.com>
    
      2pkgname=squoosh-desktop
    
      3pkgver=0.1.1
    
      4pkgrel=1
    
      5pkgdesc='Local image compressor and converter, a native port of Squoosh written in Rust'
    
      6arch=('x86_64')
    
      7url='https://github.com/hunter-gunter/squoosh-desktop'
    
      8license=('GPL-3.0-or-later' 'Apache-2.0')
    
      9depends=('glibc' 'gcc-libs' 'libwebp' 'libavif' 'lcms2' 'libxkbcommon' 'libxkbcommon-x11' 'libx11' 'libxcb' 'libglvnd' 'wayland' 'hicolor-icon-theme')
    
      10makedepends=('cargo' 'nasm' 'pkgconf')
    
      11optdepends=('xdg-desktop-portal: native file dialogs'
    
      12            'xdg-desktop-portal-gtk: file chooser portal for GTK desktops'
    
      13            'xdg-desktop-portal-kde: file chooser portal for KDE Plasma')
    
      14# Cargo applies its own ThinLTO; makepkg's linker-plugin LTO drops bundled C objects.
    
      15# The release profile strips the binary, so a debug package would be empty.
    
      16options=('!lto' '!debug')
    
      17source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      18sha256sums=('f1ed2448d85ee4658304b335cddae9f4c4685f108788f1134ed1b1592e165531')
    
      19
    
      20prepare() {
    
      21  cd "$pkgname-$pkgver"
    
      22  export RUSTUP_TOOLCHAIN=stable
    
      23  cargo fetch --locked --target "$(rustc --print host-tuple)"
    
      24}
    
      25
    
      26build() {
    
      27  cd "$pkgname-$pkgver"
    
      28  export RUSTUP_TOOLCHAIN=stable
    
      29  export CARGO_TARGET_DIR=target
    
      30  cargo build --frozen --release -p squoosh-desktop
    
      31}
    
      32
    
      33check() {
    
      34  cd "$pkgname-$pkgver"
    
      35  export RUSTUP_TOOLCHAIN=stable
    
      36  export CARGO_TARGET_DIR=target
    
      37  cargo test --frozen --workspace
    
      38}
    
      39
    
      40package() {
    
      41  cd "$pkgname-$pkgver"
    
      42  install -Dm755 target/release/squoosh-desktop -t "$pkgdir/usr/bin"
    
      43  install -Dm644 packaging/squoosh-desktop.desktop -t "$pkgdir/usr/share/applications"
    
      44  install -Dm644 app/assets/icon.png "$pkgdir/usr/share/icons/hicolor/512x512/apps/squoosh-desktop.png"
    
      45  install -Dm644 README.md THIRD_PARTY.md CHANGELOG.md -t "$pkgdir/usr/share/doc/$pkgname"
    
      46  install -Dm644 LICENSE LICENSE-APACHE-2.0 -t "$pkgdir/usr/share/licenses/$pkgname"
    
      47}
    
      48

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-25 11:11:47	Low	1