ssv-network

LOW

maintainer emilbayes 0 votes scanned 2026-10-22 07:34:22.999679

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Emil Bay <archlinux@tixz.dk>
    
      2pkgname=ssv-network
    
      3_pkgname=ssv
    
      4pkgver=2.5.0
    
      5pkgrel=1
    
      6pkgdesc='Secret-Shared-Validator (SSV) node for Ethereum staking'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://ssv.network'
    
      9license=('GPL-3.0-or-later')
    
      10depends=('glibc')
    
      11makedepends=('git' 'go')
    
      12provides=('ssvnode')
    
      13conflicts=('ssvnode')
    
      14backup=('etc/ssvnode/config.yaml')
    
      15source=("${_pkgname}::git+https://github.com/ssvlabs/ssv.git#tag=v${pkgver}"
    
      16        'ssvnode.service'
    
      17        'ssvnode.sysusers'
    
      18        'ssvnode.tmpfiles')
    
      19sha256sums=('88e12c0fbfdb6d2d98ac272c8ca89503cce12aa203934a2f68387e45ca6d78f2'
    
      20            'b96f3f905287d84bab2d51ebe69d62184e7bcffc4cc1234e9431998828896565'
    
      21            'f108321762dd617d37091dc2b5ece909b8472ab7d21da0c2b0d0933fa115ae9d'
    
      22            'c985bd739b1313b53f8475f94f8b17c8397156eb8881fb2145e1e7dd9a88ae10')
    
      23
    
      24prepare() {
    
      25  cd "${_pkgname}"
    
      26  export GOPATH="${srcdir}/gopath"
    
      27  go mod download -modcacherw
    
      28}
    
      29
    
      30build() {
    
      31  cd "${_pkgname}"
    
      32  export GOPATH="${srcdir}/gopath"
    
      33  export CGO_ENABLED=1
    
      34  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      35  export CGO_CFLAGS="${CFLAGS}"
    
      36  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      37  export CGO_LDFLAGS="${LDFLAGS}"
    
      38  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    
      39
    
      40  # blst_enabled matches upstream's release builds (Dockerfile)
    
      41  go build -o bin/ssvnode \
    
      42    -tags=blst_enabled \
    
      43    -ldflags "-linkmode=external -X main.Commit=$(git rev-parse HEAD) -X main.Version=v${pkgver}" \
    
      44    ./cmd/ssvnode
    
      45}
    
      46
    
      47package() {
    
      48  cd "${_pkgname}"
    
      49  install -Dm755 bin/ssvnode "${pkgdir}/usr/bin/ssvnode"
    
      50
    
      51  # Example config with state under /var/lib/ssvnode. It will hold the operator
    
      52  # key, so tmpfiles makes it readable by the ssvnode group only.
    
      53  install -dm755 "${pkgdir}/etc/ssvnode"
    
      54  sed 's|\./data/|/var/lib/ssvnode/|' config/config.example.yaml >"${pkgdir}/etc/ssvnode/config.yaml"
    
      55  chmod 640 "${pkgdir}/etc/ssvnode/config.yaml"
    
      56  install -Dm644 config/*.example.yaml -t "${pkgdir}/usr/share/doc/${pkgname}/"
    
      57
    
      58  install -Dm644 "${srcdir}/ssvnode.service" "${pkgdir}/usr/lib/systemd/system/ssvnode.service"
    
      59  install -Dm644 "${srcdir}/ssvnode.sysusers" "${pkgdir}/usr/lib/sysusers.d/ssvnode.conf"
    
      60  install -Dm644 "${srcdir}/ssvnode.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/ssvnode.conf"
    
      61}
    
      62

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-22 07:34:22	Low	1