stealth-mission-89

LOW

maintainer dividebysandwich 0 votes scanned 2026-10-21 15:32:06.139547

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1pkgname=stealth-mission-89
    
      2pkgver=0.3.0
    
      3pkgrel=1
    
      4pkgdesc='A Rust/Bevy remake of DOS-era 3D flight simulations with VR support'
    
      5arch=('x86_64' 'aarch64')
    
      6url='https://github.com/dividebysandwich/stealth-mission-89'
    
      7license=('Apache-2.0')
    
      8depends=('alsa-lib' 'glibc' 'hicolor-icon-theme' 'libx11' 'libxcursor' 'libxi' 'libgcc'
    
      9         'libxkbcommon' 'libxrandr' 'systemd-libs' 'vulkan-icd-loader' 'wayland')
    
      10makedepends=('cargo')
    
      11optdepends=('openxr: VR headset support (--vr)')
    
      12options=('!lto')
    
      13source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      14sha256sums=('a1e96326461a2d584fab11e3b6aa3f4be174597731336ceeb1bf9591fb52df46')
    
      15
    
      16prepare() {
    
      17  cd "$pkgname-$pkgver"
    
      18  export RUSTUP_TOOLCHAIN=stable
    
      19  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      20}
    
      21
    
      22build() {
    
      23  cd "$pkgname-$pkgver"
    
      24  export RUSTUP_TOOLCHAIN=stable
    
      25  export CARGO_TARGET_DIR=target
    
      26  # Release builds drop the default `dev` feature (bevy/dynamic_linking).
    
      27  cargo build --frozen --release -p stealth-mission-89 --no-default-features \
    
      28    --features stealth-mission-89/xr
    
      29}
    
      30
    
      31package() {
    
      32  cd "$pkgname-$pkgver"
    
      33  install -Dm755 target/release/$pkgname -t "$pkgdir/usr/lib/$pkgname/"
    
      34  install -dm755 "$pkgdir/usr/share/$pkgname"
    
      35  cp -r --no-preserve=ownership assets "$pkgdir/usr/share/$pkgname/"
    
      36
    
      37  # The game reads its assets from $BEVY_ASSET_ROOT; saves and settings go to the XDG dirs.
    
      38  install -dm755 "$pkgdir/usr/bin"
    
      39  cat > "$pkgdir/usr/bin/$pkgname" <<EOF
    
      40#!/bin/sh
    
      41export BEVY_ASSET_ROOT="\${BEVY_ASSET_ROOT:-/usr/share/$pkgname}"
    
      42exec /usr/lib/$pkgname/$pkgname "\$@"
    
      43EOF
    
      44  chmod 755 "$pkgdir/usr/bin/$pkgname"
    
      45
    
      46  install -Dm644 packaging/linux/$pkgname.desktop -t "$pkgdir/usr/share/applications/"
    
      47  install -Dm644 packaging/linux/$pkgname.png -t "$pkgdir/usr/share/icons/hicolor/256x256/apps/"
    
      48  install -Dm644 packaging/linux/$pkgname.svg -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
    
      49  install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
    
      50  cp -r --no-preserve=ownership docs/. "$pkgdir/usr/share/doc/$pkgname/"
    
      51}
    
      52

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-21 15:32:06	Low	1