stoolap-git

maintainer VZstless · 0 votes · scanned 2026-08-03 00:08:14.047287

LOW

Why flagged The package builds from the project's own Git repository, which is normal for AUR packages; the low severity is due to few votes and recent upload, not malicious content.

Triggered rules

LOW Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

LOW AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from the project's own Git repository, which is normal for AUR packages; the low severity is due to few votes and recent upload, not malicious content.

PKGBUILD

      1# Maintainer: VZstless <i [at] vzstless [dot] moe>
    
      2
    
      3pkgname=stoolap-git
    
      4pkgver=0.4.0.r23.g7e6634b
    
      5pkgrel=1
    
      6pkgdesc="Modern Embedded SQL Database written in Rust"
    
      7arch=('x86_64')
    
      8url="https://github.com/stoolap/stoolap"
    
      9license=("Apache-2.0")
    
      10makedepends=("rust" "git")
    
      11options=('!lto')
    
      12provides=('stoolap')
    
      13conflicts=('stoolap')
    
      14source=("$pkgname::git+$url")
    
      15b2sums=('SKIP')
    
      16
    
      17pkgver() {
    
      18    cd "$pkgname"
    
      19    git describe --long --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      20}
    
      21
    
      22prepare() {
    
      23    cd "$pkgname"
    
      24    export RUSTUP_TOOLCHAIN=stable
    
      25    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      26}
    
      27
    
      28build() {
    
      29    cd "$pkgname"
    
      30    export RUSTUP_TOOLCHAIN=stable
    
      31    export CARGO_TARGET_DIR=target
    
      32    cargo build --frozen --release --all-features
    
      33}
    
      34
    
      35check() {
    
      36    cd "$pkgname"
    
      37    export RUSTUP_TOOLCHAIN=stable
    
      38    cargo test --frozen --all-features
    
      39}
    
      40
    
      41package() {
    
      42    cd "$pkgname"
    
      43    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/stoolap"
    
      44    install -Dm0644 -t "$pkgdir/usr/share/licenses/stoolap/" "LICENSE"
    
      45}
    
      46

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-03 00:08:14	LOW	2
2026-08-02 00:16:08	LOW	2
2026-08-01 00:11:18	LOW	2
2026-07-31 00:14:10	LOW	2
2026-07-30 00:17:23	LOW	2
2026-07-29 00:25:53	LOW	2
2026-07-28 17:39:33	LOW	2