systemd-libs-selinux

LOW
maintainer IooNag 19 votes base systemd-selinux scanned 2026-11-01 00:21:48.120785
View on AUR
Why flagged

The flagged pattern involves self-installation via pacman hooks and systemd service management, which is normal for systemd packages and not inherently dangerous.

Triggered rules

Low AI review downgraded a static finding llm_review

The static rules flagged this MEDIUM, but an AI model (qwen/qwen3-235b-a22b-2507) reviewed the full PKGBUILD and judged it LOW (confidence 95%): The flagged pattern involves self-installation via pacman hooks and systemd service management, which is normal for systemd packages and not inherently dangerous.

1 higher static finding superseded - not the current verdict (shown for transparency)
Medium Privileged / out-of-pacman install (sudoers, setuid, or self-update) privileged_install

The package grants elevated privileges or installs an update path outside pacman: a /etc/sudoers.d rule (often passwordless), a setuid/setgid binary, or a self-update script/service that can fetch and run future code with no checksum verification. The initial install may be verified, but the ongoing privilege + update surface is a real supply-chain / privilege-escalation risk.

  • PKGBUILD:302 install -d -o root -g root -m 2755 "$pkgdir"/var/log/journal

PKGBUILD

1 offending line(s) highlighted
1# Maintainer: Christian Hesse <mail@eworm.de>
2# SELinux Maintainer: Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
3# SELinux Contributor: Timothée Ravier <tim@siosm.fr>
4# SELinux Contributor: Nicky726 <Nicky726@gmail.com>
5#
6# This PKGBUILD is maintained on https://github.com/archlinuxhardened/selinux.
7# If you want to help keep it up to date, please open a Pull Request there.
8
9# ➡️ Pushing pre-releases to [core-testing] can cause havoc, especially
10# as all [core] packages are built there, and may be moved before.
11# Anyway, pre-release packages may be available in my personal testing
12# repository. Brave souls add it with:
13# [eworm-testing]
14# SigLevel = Required
15# Server = https://pkgbuild.com/~eworm/$repo/$arch/
16
17pkgbase=systemd-selinux
18pkgname=('systemd-selinux'
19 'systemd-libs-selinux'
20 'systemd-resolvconf-selinux'
21 'systemd-sysvcompat-selinux'
22 'systemd-tests-selinux'
23 'systemd-ukify-selinux')
24# Upstream versioning is incompatible with pacman's version comparisons, one
25# way or another. We use proper version for pacman here (no dash for rc
26# release!), and change in source array below.
27pkgver=262
28pkgrel=1
29arch=('x86_64' 'aarch64')
30license=('LGPL-2.1-or-later')
31url='https://www.github.com/systemd/systemd'
32groups=('selinux')
33makedepends=('acl' 'apparmor' 'cryptsetup' 'docbook-xsl' 'gperf' 'lz4' 'xz' 'pam-selinux' 'libelf'
34 'intltool' 'iptables' 'kmod' 'libarchive' 'libidn2' 'libgcrypt'
35 'libmicrohttpd' 'libxcrypt' 'libxslt' 'util-linux' 'linux-api-headers'
36 'python-jinja' 'python-lxml' 'quota-tools' 'shadow-selinux' 'git'
37 'meson' 'libseccomp' 'pcre2' 'audit' 'kexec-tools' 'libxkbcommon'
38 'bash-completion' 'p11-kit' 'systemd' 'libfido2' 'tpm2-tss' 'rsync'
39 'bpf' 'libbpf' 'clang' 'llvm' 'curl' 'gnutls' 'python-pyelftools'
40 'libpwquality' 'qrencode' 'lib32-gcc-libs' 'python-pefile' 'linux-headers' 'libselinux')
41conflicts=("mkinitcpio<38-1")
42validpgpkeys=('63CDA1E5D3FC22B998D20DD6327F26951A015CC4' # Lennart Poettering <lennart@poettering.net>
43 'A9EA9081724FFAE0484C35A1A81CEA22BC8C7E2E' # Luca Boccassi <luca.boccassi@gmail.com>
44 '9A774DB5DB996C154EBBFBFDA0099A18E29326E1' # Yu Watanabe <watanabe.yu+github@gmail.com>
45 '5C251B5FC54EB2F80F407AAAC54CA336CFEB557E') # Zbigniew Jędrzejewski-Szmek <zbyszek@in.waw.pl>
46# For pacman's version comparisons $pkgver is missing the dash that would be
47# in an upstream rc version so add it back when fetching the tag from github.
48source=("git+https://github.com/systemd/systemd#tag=v${pkgver/rc/-rc}?signed"
49 '0001-Use-Arch-Linux-device-access-groups.patch'
50 # bootloader files
51 'arch.conf'
52 'loader.conf'
53 'splash-arch.bmp::https://raw.githubusercontent.com/archlinux/svntogit-packages/391c1f5d4a18d08be809caa08c769ef9cded28db/trunk/splash-arch.bmp'
54 # pam configuration
55 'systemd-user.pam'
56 # pacman / libalpm hooks
57 'systemd-hook'
58 '20-systemd-sysusers.hook'
59 '21-systemd-tmpfiles.hook'
60 '25-systemd-binfmt.hook'
61 '25-systemd-catalog.hook'
62 '25-systemd-hwdb.hook'
63 '25-systemd-sysctl.hook'
64 '30-systemd-daemon-reload-system.hook'
65 '30-systemd-daemon-reload-user.hook'
66 '35-systemd-enqueue-marked.hook'
67 '35-systemd-udev-reload.hook'
68 '35-systemd-update.hook'
69 '36-systemd-modules-load.hook')
70sha512sums=('7f6b18684e8e696e0fa6fff45213d64a9bd54e6075d8950f8e5679fe14c92737cdc3a54b58a60f68867d95bad8736584e8036fc09bbd5752ee8026308f76493f'
71 'ddb9401e47d0bf01874f255803a4b2167ec631484189d29d03694101fd9c77724e735f16d99c5f4ffd8061ae78839b2826ff0e0a925a6f0dbca25f2cfb271a82'
72 '61032d29241b74a0f28446f8cf1be0e8ec46d0847a61dadb2a4f096e8686d5f57fe5c72bcf386003f6520bc4b5856c32d63bf3efe7eb0bc0deefc9f68159e648'
73 '3194d1f8bff31b88a79657df83632b9224b66ca2cf8fd806a3ef35cf7a43f46c09c57f3dfd02256a99b6514a8f789b7d3bcfd7e17e00e34aa55ff0c6cedb5f01'
74 '5a1d78b5170da5abe3d18fdf9f2c3a4d78f15ba7d1ee9ec2708c4c9c2e28973469bc19386f70b3cf32ffafbe4fcc4303e5ebbd6d5187a1df3314ae0965b25e75'
75 '30a408b5491ea59ec6ff6e773ea587fe12900c9b8169a0e16451d1cc6a452f2424e6ce1ee595448ff009b88fcbadf4cc4ae70a553235bae4a31aa1ec12a0c777'
76 'f2f9c8de7fc10c84f8ad4b3286c6878d35cf80ac9841a55759db46f40e69b012b2d6a6638fb107a442c6e545558f864af1477f701bc0693dc452772be232b7a7'
77 '299dcc7094ce53474521356647bdd2fb069731c08d14a872a425412fcd72da840727a23664b12d95465bf313e8e8297da31259508d1c62cc2dcea596160e21c5'
78 'da7a97d5d3701c70dd5388b0440da39006ee4991ce174777931fea2aa8c90846a622b2b911f02ae4d5fffb92680d9a7e211c308f0f99c04896278e2ee0d9a4dc'
79 '0d6bc3d928cfafe4e4e0bc04dbb95c5d2b078573e4f9e0576e7f53a8fab08a7077202f575d74a3960248c4904b5f7f0661bf17dbe163c524ab51dd30e3cb80f7'
80 '2b50b25e8680878f7974fa9d519df7e141ca11c4bfe84a92a5d01bb193f034b1726ea05b3c0030bad1fbda8dbb78bf1dc7b73859053581b55ba813c39b27d9dc'
81 'a1661ab946c6cd7d3c6251a2a9fd68afe231db58ce33c92c42594aedb5629be8f299ba08a34713327b373a3badd1554a150343d8d3e5dfb102999c281bd49154'
82 '9426829605bbb9e65002437e02ed54e35c20fdf94706770a3dc1049da634147906d6b98bf7f5e7516c84068396a12c6feaf72f92b51bdf19715e0f64620319de'
83 'a436d3f5126c6c0d6b58c6865e7bd38dbfbfb7babe017eeecb5e9d162c21902cbf4e0a68cf3ac2f99815106f9fa003b075bd2b4eb5d16333fa913df6e2f3e32a'
84 '190112e38d5a5c0ca91b89cd58f95595262a551530a16546e1d84700fc9644aa2ca677953ffff655261e8a7bff6e6af4e431424df5f13c00bc90b77c421bc32d'
85 '51ebf20a1c93c2a86e8ced0d68e91f4a2bf6a537a2d674e05da69961d5861213159e28f228ffdc897bed721abd61ff133f49aeb0a9ebbbe76020c5b847c2a2df'
86 'a50d202a9c2e91a4450b45c227b295e1840cc99a5e545715d69c8af789ea3dd95a03a30f050d52855cabdc9183d4688c1b534eaa755ebe93616f9d192a855ee3'
87 '825b9dd0167c072ba62cabe0677e7cd20f2b4b850328022540f122689d8b25315005fa98ce867cf6e7460b2b26df16b88bb3b5c9ebf721746dce4e2271af7b97'
88 '717d93fb29034398394b68510f53da8d599cb68accf1cb92baee158fca1fde3fa5a1f698d35f81661b22c7acec6da34422b852e29dbc731b296a0884ffb6fcb0')
89
90_meson_version="${pkgver}-${pkgrel}"
91_systemd_src_dir="${pkgbase/-selinux}"
92
93if ((_systemd_UPSTREAM)); then
94 _meson_version="${pkgver}"
95fi
96
97# Some heuristics to detect that we are building on OBS, with no network access. Skip
98# git verification, and use the OBS-provided tarball instead. The sources will be
99# unpacked by OBS in $package-$version/
100# SELinux package maintenance note: ignore this, as skipping any form of validation is dangerous
101#if [ -f /.build/build.dist ] && [ -d /usr/src/packages/SOURCES ] && [ -d /usr/src/packages/BUILD ] && [ -d /usr/src/packages/OTHER ]; then
102# source[0]="$(find . -name "${pkgbase}-${pkgver}.tar.*" -print -quit)"
103# sha512sums[0]='SKIP'
104# _systemd_src_dir="${pkgbase}-${pkgver}"
105#fi
106
107_backports=(
108)
109
110_reverts=(
111)
112
113prepare() {
114 cd "${_systemd_src_dir}"
115
116 # return if not a git repository
117 if ! git status >/dev/null 2>&1; then
118 return
119 fi
120
121 local _c _l
122 for _c in "${_backports[@]}"; do
123 if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
124 git log --oneline "${_l}" "${_c}"
125 git cherry-pick --mainline 1 --no-commit "${_c}"
126 done
127 for _c in "${_reverts[@]}"; do
128 if [[ "${_c}" == *..* ]]; then _l='--reverse'; else _l='--max-count=1'; fi
129 git log --oneline "${_l}" "${_c}"
130 git revert --mainline 1 --no-commit "${_c}"
131 done
132
133 # Replace cdrom/dialout/tape groups with optical/uucp/storage
134 patch -Np1 -i ../0001-Use-Arch-Linux-device-access-groups.patch
135}
136
137build() {
138 local _timeservers=({0..3}.arch.pool.ntp.org)
139 local _nameservers=(
140 # We use these public name services, ordered by their privacy policy (hopefully):
141 # * Quad9 (https://quad9.net/privacy/policy/)
142 '9.9.9.9#dns.quad9.net'
143 '2620:fe::9#dns.quad9.net'
144 # * Cloudflare (https://developers.cloudflare.com/1.1.1.1/privacy/public-dns-resolver/)
145 '1.1.1.1#cloudflare-dns.com'
146 '2606:4700:4700::1111#cloudflare-dns.com'
147 # * Google (https://developers.google.com/speed/public-dns/privacy)
148 '8.8.8.8#dns.google'
149 '2001:4860:4860::8888#dns.google'
150 # You do not agree? Fine, change it in your local configuration.
151 )
152
153 local _meson_options=(
154 -Dversion-tag="${_meson_version}-arch"
155 -Dvcs-tag=false
156 -Dshared-lib-tag="${_meson_version}"
157 -Dmode=release
158
159 -Dapparmor=enabled
160 -Dbootloader=enabled
161 -Dxenctrl=disabled
162 -Dbpf-framework=enabled
163 -Dima=false
164 -Dinstall-tests=true
165 -Dlibidn2=enabled
166 -Dlz4=enabled
167 -Dman=enabled
168 -Dselinux=enabled
169 -Dsshdprivsepdir=/usr/share/empty.sshd
170 -Dsysupdated=enabled
171 -Dvmlinux-h=provided
172 -Dvmlinux-h-path=/usr/src/linux/vmlinux.h
173
174 -Dcompat-sysv-interfaces=false
175 -Ddbuspolicydir=/usr/share/dbus-1/system.d
176 -Ddefault-dnssec=no
177 -Ddefault-kill-user-processes=false
178 -Ddefault-locale='C.UTF-8'
179 -Dlocalegen-path=/usr/bin/locale-gen
180 -Ddns-over-tls=openssl
181 -Dfallback-hostname='archlinux'
182 -Dnologin-path=/usr/bin/nologin
183 -Dntp-servers="${_timeservers[*]}"
184 -Ddns-servers="${_nameservers[*]}"
185 -Drpmmacrosdir=no
186
187 -Dsbat-distro='arch'
188 -Dsbat-distro-summary='Arch Linux'
189 -Dsbat-distro-pkgname="${pkgname}"
190 -Dsbat-distro-version="${pkgver}"
191 -Dsbat-distro-url="https://aur.archlinux.org/packages/${pkgname}/"
192 )
193
194 arch-meson "${_systemd_src_dir}" build "${_meson_options[@]}" $MESON_EXTRA_CONFIGURE_OPTIONS
195
196 meson compile -C build
197}
198
199check() {
200 meson test -C build --print-errorlogs
201}
202
203package_systemd-selinux() {
204 pkgdesc='system and service manager with SELinux support'
205 license+=(
206 'CC0-1.0' # siphash
207 'GPL-2.0-or-later' # udev
208 'MIT-0' # documentation and config files
209 )
210 depends=(
211 "systemd-libs-selinux=${pkgver}"
212 'acl' 'bash' 'cryptsetup' 'dbus'
213 'dbus-units' 'glibc' 'kbd' 'kmod' 'hwdata'
214 'libgcrypt' 'libxcrypt' 'libidn2' 'lz4' 'pam-selinux'
215 'libelf' 'libgcc' 'libseccomp' 'util-linux-selinux' 'xz' 'pcre2' 'audit'
216 'openssl')
217 provides=('nss-myhostname' "systemd-tools=$pkgver" "udev=$pkgver"
218 "${pkgname/-selinux}=${pkgver}-${pkgrel}")
219 conflicts=('nss-myhostname' 'systemd-tools' 'udev'
220 "${pkgname/-selinux}" 'selinux-systemd')
221 optdepends=(
222 'apparmor: additional security features'
223 'curl: systemd-journal-upload, machinectl pull-tar and pull-raw'
224 'gnutls: systemd-journal-gatewayd and systemd-journal-remote'
225 'iptables: firewall features'
226 'libarchive: convert DDIs to tarballs'
227 'libbpf: support BPF programs'
228 'libfido2: unlocking LUKS2 volumes with FIDO2 token'
229 'libmicrohttpd: systemd-journal-gatewayd and systemd-journal-remote'
230 'libp11-kit: support PKCS#11'
231 'libpwquality: check password quality'
232 'polkit: allow administration as unprivileged user'
233 'qemu-base: systemd-vmspawn'
234 'qrencode: show QR codes'
235 'quota-tools: kernel-level quota management'
236 'systemd-sysvcompat: symlink package to provide sysvinit binaries'
237 'systemd-ukify: combine kernel and initrd into a signed Unified Kernel Image'
238 'tpm2-tss: unlocking LUKS2 volumes with TPM2')
239 backup=(etc/systemd/coredump.conf
240 etc/systemd/homed.conf
241 etc/systemd/journald.conf
242 etc/systemd/journal-remote.conf
243 etc/systemd/journal-upload.conf
244 etc/systemd/logind.conf
245 etc/systemd/networkd.conf
246 etc/systemd/oomd.conf
247 etc/systemd/pstore.conf
248 etc/systemd/resolved.conf
249 etc/systemd/sleep.conf
250 etc/systemd/system.conf
251 etc/systemd/timesyncd.conf
252 etc/systemd/user.conf
253 etc/udev/iocost.conf
254 etc/udev/udev.conf)
255 install=systemd.install
256
257 meson install -C build --no-rebuild --destdir "$pkgdir" --quiet
258
259 # runtime libraries shipped with systemd-libs
260 install -d -m0755 systemd-libs/lib/
261 mv "$pkgdir"/usr/lib/lib{nss,systemd,udev}*.so* systemd-libs/lib/
262 mv "$pkgdir"/usr/lib/pkgconfig systemd-libs/lib/pkgconfig
263 mv "$pkgdir"/usr/include systemd-libs/include
264 mv "$pkgdir"/usr/share/man/man3 systemd-libs/man3
265 install -d -m0755 systemd-libs/man8/
266 mv "$pkgdir"/usr/share/man/man8/*nss* systemd-libs/man8/
267
268 # ukify shipped in separate package
269 install -d -m0755 systemd-ukify/{bin,systemd,man1,install.d}
270 mv "$pkgdir"/usr/bin/ukify systemd-ukify/bin/
271 mv "$pkgdir"/usr/lib/systemd/ukify systemd-ukify/systemd/
272 mv "$pkgdir"/usr/share/man/man1/ukify.1 systemd-ukify/man1/
273 # we move the ukify hook itself, but keep 90-uki-copy.install in place,
274 # because there are other ways to generate UKIs w/o ukify, e.g. w/ mkinitcpio
275 mv "$pkgdir"/usr/lib/kernel/install.d/60-ukify.install systemd-ukify/install.d
276
277 # manpages shipped with systemd-sysvcompat
278 rm "$pkgdir"/usr/share/man/man1/init.1
279 rm "$pkgdir"/usr/share/man/man8/{halt,poweroff,reboot,shutdown}.8
280
281 # executable (symlinks) shipped with systemd-sysvcompat
282 rm "$pkgdir"/usr/bin/{halt,init,poweroff,reboot,shutdown}
283
284 # files shipped with systemd-resolvconf
285 rm "$pkgdir"/usr/{bin/resolvconf,share/man/man1/resolvconf.1}
286
287 # tests shipped with systemd-tests (for upstream)
288 install -d -m0755 systemd-tests/
289 mv "$pkgdir"/usr/lib/systemd/tests systemd-tests/
290
291 # avoid a potential conflict with [core]/filesystem
292 rm "$pkgdir"/usr/share/factory/etc/{issue,nsswitch.conf}
293 sed -i -e '/^C \/etc\/nsswitch\.conf/d' \
294 -e '/^C \/etc\/issue/d' "$pkgdir"/usr/lib/tmpfiles.d/etc.conf
295
296 # ship default policy to leave services disabled
297 echo 'disable *' >"$pkgdir"/usr/lib/systemd/system-preset/99-default.preset
298
299 # The group 'systemd-journal' is allocated dynamically and may have varying
300 # gid on different systems. Let's install with gid 0 (root), systemd-tmpfiles
301 # will fix the permissions for us. (see /usr/lib/tmpfiles.d/systemd.conf)
302 install -d -o root -g root -m 2755 "$pkgdir"/var/log/journal
303
304 # add example bootctl configuration
305 install -D -m0644 arch.conf "$pkgdir"/usr/share/systemd/bootctl/arch.conf
306 install -D -m0644 loader.conf "$pkgdir"/usr/share/systemd/bootctl/loader.conf
307 install -D -m0644 splash-arch.bmp "$pkgdir"/usr/share/systemd/bootctl/splash-arch.bmp
308
309 # pacman hooks
310 install -D -m0755 systemd-hook "$pkgdir"/usr/share/libalpm/scripts/systemd-hook
311 install -D -m0644 -t "$pkgdir"/usr/share/libalpm/hooks *.hook
312
313 # overwrite the systemd-user PAM configuration with our own
314 install -D -m0644 systemd-user.pam "$pkgdir"/usr/lib/pam.d/systemd-user
315
316 # create a directory for cryptsetup keys
317 install -d -m0700 "$pkgdir"/etc/cryptsetup-keys.d
318
319 # handle uncommon license
320 install -d -m0755 "$pkgdir/usr/share/licenses/$pkgbase"
321 ln -s -t "$_" /usr/share/doc/systemd/LICENSES/MIT-0.txt
322
323 # symlink kernel-install to installkernel
324 ln -s kernel-install "$pkgdir"/usr/bin/installkernel
325 ln -s kernel-install.8.gz "$pkgdir"/usr/share/man/man8/installkernel.8.gz
326}
327
328package_systemd-libs-selinux() {
329 pkgdesc='systemd client libraries with SELinux support'
330 depends=('glibc' 'libgcc' 'libgcc_s.so' 'libgcrypt' 'lz4' 'xz' 'zstd' 'libselinux')
331 license+=(
332 'CC0-1.0' # siphash
333 'GPL-2.0-or-later WITH Linux-syscall-note' # src/basic/linux/*
334 )
335 provides=('libsystemd' 'libsystemd.so' 'libudev.so'
336 'libsystemd-selinux'
337 "${pkgname/-selinux}=${pkgver}-${pkgrel}")
338 conflicts=('libsystemd' 'libsystemd-selinux' "${pkgname/-selinux}")
339 replaces=('libsystemd-selinux')
340
341 install -d -m0755 "$pkgdir"/usr/share/man
342 mv systemd-libs/lib "$pkgdir"/usr/lib
343 mv systemd-libs/include "$pkgdir"/usr/include
344 mv systemd-libs/man3 "$pkgdir"/usr/share/man/man3
345 mv systemd-libs/man8 "$pkgdir"/usr/share/man/man8
346}
347
348package_systemd-resolvconf-selinux() {
349 pkgdesc='systemd resolvconf replacement with SELinux support (for use with systemd-resolved)'
350 depends=("systemd-selinux=${pkgver}")
351 provides=('openresolv' 'resolvconf' "${pkgname/-selinux}=${pkgver}-${pkgrel}")
352 conflicts=('resolvconf' "${pkgname/-selinux}=${pkgver}-${pkgrel}")
353
354 install -d -m0755 "$pkgdir"/usr/bin
355 ln -s resolvectl "$pkgdir"/usr/bin/resolvconf
356
357 install -d -m0755 "$pkgdir"/usr/share/man/man1
358 ln -s resolvectl.1.gz "$pkgdir"/usr/share/man/man1/resolvconf.1.gz
359}
360
361package_systemd-sysvcompat-selinux() {
362 pkgdesc='sysvinit compat for systemd with SELinux support'
363 conflicts=('sysvinit' "${pkgname/-selinux}" 'selinux-systemd-sysvcompat')
364 depends=("systemd-selinux=${pkgver}")
365 provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}"
366 "selinux-systemd-sysvcompat=${pkgver}-${pkgrel}")
367
368 install -D -m0644 -t "$pkgdir"/usr/share/man/man1 \
369 build/man/init.1
370 install -D -m0644 -t "$pkgdir"/usr/share/man/man8 \
371 build/man/{halt,poweroff,reboot,shutdown}.8
372
373 install -d -m0755 "$pkgdir"/usr/bin
374 ln -s ../lib/systemd/systemd "$pkgdir"/usr/bin/init
375 for tool in halt poweroff reboot shutdown; do
376 ln -s systemctl "$pkgdir"/usr/bin/$tool
377 done
378}
379
380package_systemd-tests-selinux() {
381 pkgdesc='systemd tests with SELinux support'
382 provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}")
383 depends=("systemd-selinux=${pkgver}")
384
385 install -d -m0755 "$pkgdir"/usr/lib/systemd
386 mv systemd-tests/tests "$pkgdir"/usr/lib/systemd/tests
387}
388
389package_systemd-ukify-selinux() {
390 pkgdesc='Combine kernel and initrd into a signed Unified Kernel Image with SELinux support'
391 provides=('ukify' "${pkgname/-selinux}=${pkgver}-${pkgrel}")
392 depends=("systemd-selinux=${pkgver}" 'binutils' 'python-cryptography' 'python-pefile')
393 optdepends=('python-pillow: Show the size of splash image'
394 'sbsigntools: Sign the embedded kernel')
395
396 install -d -m0755 "$pkgdir"/usr/{lib/kernel,share/man}
397 mv systemd-ukify/bin "$pkgdir"/usr/bin
398 mv systemd-ukify/systemd "$pkgdir"/usr/lib/systemd
399 mv systemd-ukify/man1 "$pkgdir"/usr/share/man/man1
400 mv systemd-ukify/install.d "$pkgdir"/usr/lib/kernel/install.d
401}
402
403# vim:ft=sh syn=sh et sw=2:
404

Scan history

Scanned at (UTC)SeverityRules
2026-11-01 00:21:48 Low 2
2026-10-31 00:07:41 Low 2
2026-10-30 00:29:30 Low 2
2026-10-29 00:13:55 Low 2
2026-10-28 00:06:54 Low 2
2026-10-27 00:23:28 Low 2
2026-10-26 00:12:40 Low 2
2026-10-25 00:20:48 Low 2
2026-10-24 00:14:55 Low 2
2026-10-23 00:02:19 Low 2
2026-10-22 00:13:10 Low 2
2026-10-21 00:12:50 Low 2
2026-10-20 19:28:13 Medium 1
2026-10-20 00:10:31 Low 2
2026-10-19 00:03:55 Low 2
2026-10-18 00:06:55 Low 2
2026-10-17 00:21:55 Low 2
2026-10-16 00:12:47 Low 2
2026-10-15 00:28:05 Low 2
2026-10-14 00:06:47 Low 2

Report a package

Reports go to the AURWatch maintainer (one person) and are read by hand. No login required.

0 / 4000
Your suggestion