tar1090-git

LOW

maintainer meijin 0 votes scanned 2026-09-03 13:53:13.144096

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Assaf Sapir <assaf AT sapir.io>
    
      2pkgname=tar1090-git
    
      3pkgver=3.14.1818.r2373.g0895bdb
    
      4pkgrel=1
    
      5pkgdesc="Web interface for readsb / dump1090-fa with track history, heatmap, range outline and aircraft database"
    
      6arch=('any')
    
      7url="https://github.com/wiedehopf/tar1090"
    
      8license=('GPL-2.0-or-later')
    
      9depends=('bash' 'gzip' 'jq' 'dump1090')
    
      10makedepends=('git')
    
      11optdepends=('wget: UAT/978 and planefinder data fetch (ENABLE_978, PF_ENABLE)'
    
      12            'lighttpd: serve the web interface'
    
      13            'nginx: serve the web interface')
    
      14backup=('etc/default/tar1090' 'etc/lighttpd/conf.d/tar1090.conf')
    
      15install=tar1090.install
    
      16source=("tar1090::git+https://github.com/wiedehopf/tar1090.git"
    
      17        "tar1090-db::git+https://github.com/wiedehopf/tar1090-db.git"
    
      18        'tar1090.sysusers')
    
      19sha256sums=('SKIP'
    
      20            'SKIP'
    
      21            'SKIP')
    
      22
    
      23# where dump1090 writes aircraft.json; baked into the web server snippets, the service reads it from /etc/default/tar1090
    
      24_srcdir=/run/dump1090
    
      25_share=/usr/share/tar1090
    
      26
    
      27pkgver() {
    
      28  cd tar1090
    
      29  printf '%s.r%s.g%s' "$(cat version)" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      30}
    
      31
    
      32build() {
    
      33  # mirrors what upstream install.sh does to the html directory
    
      34  local dbver ver
    
      35  dbver=$(git -C tar1090-db rev-parse --short=7 HEAD)
    
      36  ver=$(cat tar1090/version)
    
      37  rm -rf html
    
      38  cp -r tar1090/html html
    
      39  cp -r tar1090-db/db "html/db-$dbver"
    
      40  sed -i -e "s/let databaseFolder = .*;/let databaseFolder = \"db-$dbver\";/" \
    
      41         -e "s/id=\"webinterface_version\">/&($ver)/" html/index.html
    
      42  echo "{ \"tar1090Version\": \"$ver\", \"databaseVersion\": \"$dbver\" }" > html/version.json
    
      43  (cd html && bash "$srcdir/tar1090/cachebust.sh" "$srcdir/tar1090/cachebust.list" "$srcdir/html")
    
      44
    
      45  # fill upstream's placeholders
    
      46  local subst=(-e "s?/usr/local/share/tar1090?$_share?g" -e "s?SOURCE_DIR?$_srcdir?g" -e "s/SERVICE/tar1090/g" -e "s?HTMLPATH?$_share/html?g")
    
      47  sed "${subst[@]}" -e 's/INSTANCE/tar1090/g' \
    
      48      -e 's/compress.filetype/deflate.mimetypes/' -e 's/^\([^#]*deflate.mimetypes\)/#\1/' \
    
      49      tar1090/88-tar1090.conf > lighttpd-tar1090.conf
    
      50  sed "${subst[@]}" -e 's/INSTANCE/tar1090/g' tar1090/nginx.conf > nginx-tar1090.conf
    
      51  sed "${subst[@]}" -e 's?ExecStart=.* /run/tar1090 .*?ExecStart='"$_share"'/tar1090.sh /run/tar1090 ${SOURCE_DIR}?' \
    
      52      -e 's/^After=dump1090-fa.service/After=dump1090.service/' tar1090/tar1090.service > tar1090.service
    
      53  { printf '# Directory where dump1090 writes aircraft.json\nSOURCE_DIR=%s\n\n' "$_srcdir"; cat tar1090/default; } > default
    
      54}
    
      55
    
      56package() {
    
      57  install -d "$pkgdir$_share"
    
      58  cp -r html "$pkgdir$_share/html"
    
      59  install -m755 tar1090/tar1090.sh "$pkgdir$_share/"
    
      60  install -m644 tar1090/default "$pkgdir$_share/example_config_dont_edit"
    
      61  install -m644 tar1090/html/config.js "$pkgdir$_share/example_config.js"
    
      62  install -Dm644 default "$pkgdir/etc/default/tar1090"
    
      63  install -Dm644 tar1090.service "$pkgdir/usr/lib/systemd/system/tar1090.service"
    
      64  install -Dm644 tar1090.sysusers "$pkgdir/usr/lib/sysusers.d/tar1090.conf"
    
      65  install -Dm644 lighttpd-tar1090.conf "$pkgdir/etc/lighttpd/conf.d/tar1090.conf"
    
      66  install -Dm644 nginx-tar1090.conf "$pkgdir/usr/share/doc/tar1090/nginx-tar1090.conf"
    
      67  install -Dm644 tar1090/README.md "$pkgdir/usr/share/doc/tar1090/README.md"
    
      68  install -Dm644 tar1090/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      69}
    
      70

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-03 13:53:13	Low	1