teamcity-cli-git

LOW

maintainer YummierGravy 0 votes scanned 2026-10-26 09:44:33.960329

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: YummierGravy
    
      2
    
      3pkgname=teamcity-cli-git
    
      4pkgver=1.6.0.r1.g4ef45b2
    
      5pkgrel=1
    
      6pkgdesc='Command-line interface for JetBrains TeamCity (git version)'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/JetBrains/teamcity-cli'
    
      9license=('Apache-2.0')
    
      10makedepends=('git' 'go')
    
      11provides=("${pkgname%-git}")
    
      12conflicts=("${pkgname%-git}")
    
      13source=("${pkgname}::git+${url}.git")
    
      14sha256sums=('SKIP')
    
      15
    
      16pkgver() {
    
      17  cd "$pkgname"
    
      18  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      19}
    
      20
    
      21prepare() {
    
      22  cd "$pkgname"
    
      23  export GOFLAGS="-mod=readonly"
    
      24  go mod download
    
      25}
    
      26
    
      27build() {
    
      28  cd "$pkgname"
    
      29  export CGO_ENABLED=0 DO_NOT_TRACK=1
    
      30  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    
      31  go build \
    
      32    -ldflags "-s -w -X github.com/JetBrains/teamcity-cli/internal/version.Version=${pkgver}" \
    
      33    -o teamcity ./tc
    
      34
    
      35  ./teamcity completion bash > teamcity.bash
    
      36  ./teamcity completion zsh > teamcity.zsh
    
      37  ./teamcity completion fish > teamcity.fish
    
      38}
    
      39
    
      40check() {
    
      41  cd "$pkgname"
    
      42  go test ./internal/config ./internal/output
    
      43}
    
      44
    
      45package() {
    
      46  cd "$pkgname"
    
      47  install -Dm755 teamcity -t "$pkgdir/usr/bin"
    
      48  install -Dm644 teamcity.bash "$pkgdir/usr/share/bash-completion/completions/teamcity"
    
      49  install -Dm644 teamcity.zsh "$pkgdir/usr/share/zsh/site-functions/_teamcity"
    
      50  install -Dm644 teamcity.fish "$pkgdir/usr/share/fish/vendor_completions.d/teamcity.fish"
    
      51  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
    
      52}
    
      53

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-26 09:44:33	Low	1