telegram-desktop-export

LOW
maintainer Remenod 0 votes scanned 2026-10-21 05:30:25.801317
View on AUR
Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

1# Maintainer: Remenod <remenod@gmail.com>
2# Contributor: Sven-Hendrik Haase <svenstaro@archlinux.org>
3# Contributor: hexchain <i@hexchain.org>
4# Generated from Arch Linux's extra/telegram-desktop 7.3.2-1
5# by https://github.com/Remenod/telegram-desktop-export (packaging branch).
6
7pkgname=telegram-desktop-export
8pkgver=7.3.2
9_td_commit=c15d3f5a5de6e3ba5839822c451152e5e18bb700
10_wallet_engine_ver=0.0.7
11pkgrel=1
12pkgdesc='Telegram Desktop with export patches: media reused between exports, size limits per media type, no hangs on lost media'
13arch=('x86_64')
14url="https://github.com/Remenod/telegram-desktop-export"
15license=('GPL-3.0-or-later WITH OpenSSL-exception')
16provides=('telegram-desktop')
17conflicts=('telegram-desktop')
18# LTO makes the build several times slower and hungrier.
19options=('!lto' '!debug')
20depends=(
21 'abseil-cpp'
22 'ada'
23 'cairo'
24 'ffmpeg'
25 'fontconfig'
26 'glib2'
27 'glibc'
28 'hicolor-icon-theme'
29 'hunspell'
30 'kcoreaddons'
31 'libavif'
32 'libfido2'
33 'libgcc'
34 'libheif'
35 'libjpeg-turbo'
36 'libjxl'
37 'libpipewire'
38 'libsrtp'
39 'libstdc++'
40 'libvpx'
41 'libx11'
42 'libxcb'
43 'libxcomposite'
44 'libxdamage'
45 'libxext'
46 'libxfixes'
47 'libxkbcommon'
48 'libxrandr'
49 'libxtst'
50 'lz4'
51 'minizip'
52 'openal'
53 'openh264'
54 'openssl'
55 'opus'
56 'pango'
57 'pipewire'
58 'qt6-base'
59 'qt6-declarative'
60 'qt6-imageformats'
61 'qt6-svg'
62 'qt6-wayland'
63 'rnnoise'
64 'tlottie'
65 'xxhash'
66 'zlib'
67)
68makedepends=(
69 'boost'
70 'boost-libs'
71 'cargo'
72 'cmake'
73 'git'
74 'glib2-devel'
75 'gobject-introspection'
76 'just'
77 'qt6-shadertools'
78 'gperf'
79 'libtg_owt'
80 'microsoft-gsl'
81 'ninja'
82 'python'
83 'range-v3'
84 'tl-expected'
85 'vulkan-headers'
86)
87optdepends=(
88 'geoclue: geoinformation support'
89 'crow-translate: translation provider'
90 'webkit2gtk-4.1: embedded browser features provided by webkit2gtk-4.1 (gtk3)'
91 'webkitgtk-6.0: embedded browser features provided by webkitgtk-6.0 (gtk4)'
92 'xdg-desktop-portal: desktop integration'
93)
94source=(
95 "https://github.com/telegramdesktop/tdesktop/releases/download/v${pkgver}/tdesktop-${pkgver}-full.tar.gz"
96 "git+https://github.com/tdlib/td.git#commit=${_td_commit}"
97 # We're vendoring wallet-engine because tdesktop requires a massive patch against it.
98 wallet-engine-${_wallet_engine_ver}.tar.gz::https://github.com/i582/wallet-engine/archive/refs/tags/v${_wallet_engine_ver}.tar.gz
99 https://github.com/desktop-app/patches/raw/refs/heads/master/wallet-engine.patch
100 export-patches.patch
101)
102sha512sums=('27bcf431bb4435304b4be1846b9f14ea5cfcd6a60788a78129a78cc8b5a70444d8d91f0beac7757b30df7e384452317b4aa2e809131c13d31d84db4392b6c8ea'
103 'dd4741b3621c5e76ba7c9eee44ffd41b1e6b6c24fdb19988efd780d307aff79a9dcfd710be9ad63db6857cbbd71c273c54d82be524a5326fc22f1233d9eb6ca2'
104 'f1a38de20459c5b780c98aaab037fdf34357980e7f3b93c4b523636d016ca4ffc9d9679c2ee4a246b138ef0474b8190d2db1874b204c006b0f30b3c950c62ff6'
105 '79460145f706d3eb244335700a30be2e6862db2bcda042244cf45ec5227956130a366c54a4240167327e33fde4c9fa671305a7f942acedd17e994d24e0612a2b'
106 'a68f0622ea83eedf49c7d3e43909d20552a52848d5be987a650267a9827347af47654b93ed9926c2a429bfa6eb9666eaf8a21d4c4c6fcedca269d4a6d4d67f9b')
107
108prepare() {
109 patch -Np1 -d "$srcdir/tdesktop-$pkgver-full" -i "$srcdir/export-patches.patch"
110 cd wallet-engine-${_wallet_engine_ver}
111 patch -Np1 -i "$srcdir"/wallet-engine.patch
112}
113
114build() {
115 # Build wallet-engine
116 cd wallet-engine-${_wallet_engine_ver}
117 just build
118 just bindings-cpp
119 install -Dm644 target/release/libwallet_engine.a -t install/lib/
120 install -Dm644 bindings/cpp-experimental/* -t install/include/wallet_engine/
121 cd ..
122
123 # Build td
124 cmake -S td -B td/build \
125 -DCMAKE_BUILD_TYPE=None \
126 -DCMAKE_INSTALL_PREFIX="$PWD/td/install" \
127 -Wno-dev \
128 -DTD_E2E_ONLY=ON
129 cmake --build td/build
130 cmake --install td/build
131
132 # Build tdesktop
133
134 # Turns out we're allowed to use the official API key that telegram uses for
135 # their snap builds:
136 # https://github.com/telegramdesktop/tdesktop/blob/8fab9167beb2407c1153930ed03a4badd0c2b59f/snap/snapcraft.yaml#L87-L88
137 # Thanks @primeos!
138 cmake -B build -S tdesktop-$pkgver-full -G Ninja \
139 -DCMAKE_VERBOSE_MAKEFILE=ON \
140 -DCMAKE_INSTALL_PREFIX="/usr" \
141 -Dtde2e_DIR="$PWD/td/install/lib/cmake/tde2e" \
142 -DCMAKE_PREFIX_PATH="$PWD/wallet-engine-${_wallet_engine_ver}/install" \
143 -DCMAKE_BUILD_TYPE=None \
144 -DTDESKTOP_API_ID=611335 \
145 -DTDESKTOP_API_HASH=d524b414d21f4d37f08684c1df41ac9c
146 cmake --build build
147}
148
149package() {
150 DESTDIR="$pkgdir" cmake --install build
151 [[ -e "$pkgdir/usr/bin/telegram-desktop" ]] \
152 || ln -s Telegram "$pkgdir/usr/bin/telegram-desktop"
153}
154

Changes since previous scan

--- PKGBUILD @ 2026-10-17 00:21
+++ PKGBUILD @ 2026-10-21 05:30
@@ -1,14 +1,14 @@
# Maintainer: Remenod <remenod@gmail.com>
# Contributor: Sven-Hendrik Haase <svenstaro@archlinux.org>
# Contributor: hexchain <i@hexchain.org>
-# Generated from Arch Linux's extra/telegram-desktop 7.3.1-1
+# Generated from Arch Linux's extra/telegram-desktop 7.3.2-1
# by https://github.com/Remenod/telegram-desktop-export (packaging branch).
pkgname=telegram-desktop-export
-pkgver=7.3.1
+pkgver=7.3.2
_td_commit=c15d3f5a5de6e3ba5839822c451152e5e18bb700
_wallet_engine_ver=0.0.7
-pkgrel=1.1
+pkgrel=1
pkgdesc='Telegram Desktop with export patches: media reused between exports, size limits per media type, no hangs on lost media'
arch=('x86_64')
url="https://github.com/Remenod/telegram-desktop-export"
@@ -99,11 +99,11 @@
https://github.com/desktop-app/patches/raw/refs/heads/master/wallet-engine.patch
export-patches.patch
)
-sha512sums=('da4d47678692a01acf8b84ce66a8530897853b2b94c9e77b40a3d179fd1657a08b9fd6cfc6999490cf77f0dbb9bae39e774374b391d0a85cf3318429bcd2a0bb'
+sha512sums=('27bcf431bb4435304b4be1846b9f14ea5cfcd6a60788a78129a78cc8b5a70444d8d91f0beac7757b30df7e384452317b4aa2e809131c13d31d84db4392b6c8ea'
'dd4741b3621c5e76ba7c9eee44ffd41b1e6b6c24fdb19988efd780d307aff79a9dcfd710be9ad63db6857cbbd71c273c54d82be524a5326fc22f1233d9eb6ca2'
'f1a38de20459c5b780c98aaab037fdf34357980e7f3b93c4b523636d016ca4ffc9d9679c2ee4a246b138ef0474b8190d2db1874b204c006b0f30b3c950c62ff6'
'79460145f706d3eb244335700a30be2e6862db2bcda042244cf45ec5227956130a366c54a4240167327e33fde4c9fa671305a7f942acedd17e994d24e0612a2b'
- 'a9d352570e31e84cd2c4b17b7f77d4330c5e6c0a42290bdefabc5e787880b6d27f71f8270bdf1e070960e4024d3625502a5a7b24bbeff93d33268c571a0c6646')
+ 'a68f0622ea83eedf49c7d3e43909d20552a52848d5be987a650267a9827347af47654b93ed9926c2a429bfa6eb9666eaf8a21d4c4c6fcedca269d4a6d4d67f9b')
prepare() {
patch -Np1 -d "$srcdir/tdesktop-$pkgver-full" -i "$srcdir/export-patches.patch"
@@ -116,9 +116,8 @@
cd wallet-engine-${_wallet_engine_ver}
just build
just bindings-cpp
- mkdir -p install/lib install/include/wallet_engine
- cp target/release/libwallet_engine.a install/lib/
- cp bindings/cpp-experimental/* install/include/wallet_engine/
+ install -Dm644 target/release/libwallet_engine.a -t install/lib/
+ install -Dm644 bindings/cpp-experimental/* -t install/include/wallet_engine/
cd ..
# Build td

Scan history

Scanned at (UTC)SeverityRules
2026-10-21 05:30:25 Low 1
2026-10-17 00:21:55 Clean 2
2026-10-16 13:16:10 Low 1
2026-10-16 00:12:47 Clean 2
2026-10-15 23:13:54 Low 1
2026-10-15 19:13:05 Low 1

Report a package

Reports go to the AURWatch maintainer (one person) and are read by hand. No login required.

0 / 4000
Your suggestion