tephro-server-bin

LOW

maintainer AuHunt 0 votes scanned 2026-10-20 03:27:25.773183

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Nicolas Ramirez-Diaz <support at tephro dot chat>
    
      2# The AUR's tephro-server-bin, written by `make aur SERVER=X.Y.Z` from
    
      3# server/deploy/aur/PKGBUILD.in. Edit the template in the Tephro repository,
    
      4# not the copy on the AUR.
    
      5#
    
      6# The release's own static binary, installed as /usr/bin/tephro-server, with
    
      7# the shipped systemd unit (data in /var/lib/tephro, run as the tephro user).
    
      8# The hashes come from the release's SHA256SUMS after its OpenPGP signature
    
      9# verified. pacman owns the binary, so `tephro-server admin upgrade` refuses
    
      10# to swap it and names the package command instead.
    
      11pkgname=tephro-server-bin
    
      12pkgver=0.13.0
    
      13pkgrel=1
    
      14pkgdesc="Self-hosted group chat server: text, voice, video and screen sharing in one binary (release build)"
    
      15arch=('x86_64' 'aarch64')
    
      16url="https://tephro.chat"
    
      17license=('AGPL-3.0-or-later')
    
      18depends=()
    
      19provides=('tephro-server')
    
      20conflicts=('tephro-server')
    
      21options=('!strip' '!debug')
    
      22source=('tephro-server.service' 'tephro-server.sysusers' 'tephro-server.tmpfiles')
    
      23source_x86_64=("tephro-${pkgver}-linux-amd64::https://gitlab.com/encenillo/tephro/-/releases/server%2Fv${pkgver}/downloads/tephro-${pkgver}-linux-amd64")
    
      24source_aarch64=("tephro-${pkgver}-linux-arm64::https://gitlab.com/encenillo/tephro/-/releases/server%2Fv${pkgver}/downloads/tephro-${pkgver}-linux-arm64")
    
      25sha256sums=('cc33d30fe1efec74ef78c23e6f574feaf7335519504365e6084215c4643b83be' '244b6d13190d4fdc1c92fee072484fad83a4f4bcbc7d3ba29ce683a3a6dd4d57' 'd2058578c4b27880a4fd6cedfe3956e9591c7afd240e11f8c78b55b4f3ceb57e')
    
      26sha256sums_x86_64=('3f56ef9dfae59d4738d7b78fee2845c2c21064119fffbfe659e7ed13c3caced6')
    
      27sha256sums_aarch64=('a8fcda8ac32ce57e499287e42cc6dd02ffa184a1f4b4bfaabac40359ccde3038')
    
      28
    
      29package() {
    
      30  local goarch=amd64
    
      31  [[ $CARCH == aarch64 ]] && goarch=arm64
    
      32  install -Dm755 "tephro-${pkgver}-linux-${goarch}" "$pkgdir/usr/bin/tephro-server"
    
      33  sed 's|/usr/local/bin/tephro-server|/usr/bin/tephro-server|' tephro-server.service > tephro-server.service.pkg
    
      34  install -Dm644 tephro-server.service.pkg "$pkgdir/usr/lib/systemd/system/tephro-server.service"
    
      35  install -Dm644 tephro-server.sysusers "$pkgdir/usr/lib/sysusers.d/tephro-server.conf"
    
      36  install -Dm644 tephro-server.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/tephro-server.conf"
    
      37}
    
      38

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-20 03:27:25	Low	1
2026-10-20 00:10:31	Clean	2
2026-10-19 23:26:39	Low	1