tonepush-git

maintainer crmne · 0 votes · scanned 2026-08-18 00:03:42.021799

LOW

Why flagged The package builds from a public Git repository with a SKIP'd checksum, but it is the project's own source code and not an unverifiable binary; the low severity is due to limited votes and recent upload, not malicious content.

Triggered rules

LOW Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

LOW AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from a public Git repository with a SKIP'd checksum, but it is the project's own source code and not an unverifiable binary; the low severity is due to limited votes and recent upload, not malicious content.

PKGBUILD

      1# Maintainer: Carmine Paolino <carmine@paolino.me>
    
      2pkgname=tonepush-git
    
      3pkgver=0.5.0.r0.0ef5af5
    
      4pkgrel=1
    
      5pkgdesc="Open-source editor for Line 6 Helix and HX pedals, with a GUI and a scriptable CLI"
    
      6arch=('x86_64' 'aarch64')
    
      7url="https://tonepush.rocks"
    
      8license=('MIT')
    
      9install="${pkgname}.install"
    
      10makedepends=('git' 'cargo' 'libxkbcommon' 'wayland' 'mesa')
    
      11optdepends=('libgl: for the GUI'
    
      12            'libxkbcommon: for the GUI'
    
      13            'wayland: for the GUI on Wayland'
    
      14            'libx11: for the GUI on X11'
    
      15            'p7zip: extract HX Edit model data from inside the app')
    
      16provides=('tonepush')
    
      17conflicts=('tonepush' 'stompchain-git')
    
      18replaces=('stompchain-git')
    
      19# !lto because ring compiles its own C and Arch's default CFLAGS put LTO
    
      20# objects in the archive, which lld then cannot resolve: the link fails on
    
      21# undefined ring_core_* symbols. The stable package is prebuilt and never meets
    
      22# this.
    
      23options=('!debug' '!lto')
    
      24source=("${pkgname}::git+https://github.com/crmne/tonepush.git")
    
      25sha256sums=('SKIP')
    
      26
    
      27pkgver() {
    
      28  cd "${srcdir}/${pkgname}"
    
      29  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\-/.r/;s/\-g/./'
    
      30}
    
      31
    
      32prepare() {
    
      33  cd "${srcdir}/${pkgname}"
    
      34  export RUSTUP_TOOLCHAIN=stable
    
      35  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      36}
    
      37
    
      38build() {
    
      39  cd "${srcdir}/${pkgname}"
    
      40  export RUSTUP_TOOLCHAIN=stable
    
      41  export CARGO_TARGET_DIR=target
    
      42  # Generated bindings inside glutin carry the path they were built at, which
    
      43  # ends up in the binary and makes makepkg warn about a reference to $srcdir.
    
      44  # Appended rather than assigned, so the distro's own flags survive.
    
      45  export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=${srcdir}=/"
    
      46  # The editor and the CLI by name. Building the whole workspace would drag in
    
      47  # the Ruby extension, which links against libruby and is nothing to do with
    
      48  # this package.
    
      49  cargo build --frozen --release -p hx-cli -p hx-gui
    
      50}
    
      51
    
      52check() {
    
      53  cd "${srcdir}/${pkgname}"
    
      54  export RUSTUP_TOOLCHAIN=stable
    
      55  # Needs no hardware; the tests that talk to a device are #[ignore]d.
    
      56  cargo test --frozen -p hx-proto -p hx-catalog -p hx-cli -p hx-gui
    
      57}
    
      58
    
      59package() {
    
      60  cd "${srcdir}/${pkgname}"
    
      61
    
      62  install -Dm755 "target/release/tonepush" "${pkgdir}/usr/bin/tonepush"
    
      63  install -Dm755 "target/release/tonepush-gui" "${pkgdir}/usr/bin/tonepush-gui"
    
      64  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      65  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      66  install -Dm644 "packaging/applications/tonepush.desktop" \
    
      67    "${pkgdir}/usr/share/applications/tonepush.desktop"
    
      68  install -Dm644 "packaging/icons/tonepush.svg" \
    
      69    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/tonepush.svg"
    
      70  install -Dm644 "packaging/udev/70-line6-hx.rules" \
    
      71    "${pkgdir}/usr/lib/udev/rules.d/70-line6-hx.rules"
    
      72}
    
      73

Changes since previous scan

--- PKGBUILD @ 2026-08-16 00:03
+++ PKGBUILD @ 2026-08-18 00:03
@@ -1,6 +1,6 @@
 # Maintainer: Carmine Paolino <carmine@paolino.me>
 pkgname=tonepush-git
-pkgver=0.4.1.r0.fa7ad09
+pkgver=0.5.0.r0.0ef5af5
 pkgrel=1
 pkgdesc="Open-source editor for Line 6 Helix and HX pedals, with a GUI and a scriptable CLI"
 arch=('x86_64' 'aarch64')

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-18 00:03:42	LOW	2
2026-08-17 00:18:29	LOW	2
2026-08-16 19:33:38	LOW	2
2026-08-16 00:03:42	CLEAN	2
2026-08-15 13:30:33	LOW	1
2026-08-15 11:30:23	LOW	1
2026-08-12 00:27:08	CLEAN	2
2026-08-11 13:21:13	LOW	1