trae-ide

MEDIUM

maintainer lzsnyy 0 votes scanned 2026-11-03 12:09:28.176153

View on AUR

Why flagged

Installs a prebuilt proprietary binary IDE downloaded from lf-cdn.trae.com.cn (ByteDance's CDN), which is plausibly the official distribution host for Trae IDE; checksums are provided but the binary is closed-source and unverifiable, representing a typical medium-risk prebuilt binary package rather than anything actively malicious.

Triggered rules

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:19 source_x86_64=("Trae-linux-x64-${pkgver}-${pkgrel}.tar.gz::https://lf-cdn.trae.com.cn/obj/trae-com-cn/pkg/app/releases/stable/2.3.93439/linux/TRAE-linux-x64.tar.gz")

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Medium AI review llm_review

An AI model (anthropic/claude-sonnet-4.6) reviewed this and agrees it is MEDIUM (confidence 70%): Installs a prebuilt proprietary binary IDE downloaded from lf-cdn.trae.com.cn (ByteDance's CDN), which is plausibly the official distribution host for Trae IDE; checksums are provided but the binary is closed-source and unverifiable, representing a typical medium-risk prebuilt binary package rather than anything actively malicious.

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: lzsnyy <710080675@qq.com>
    
      2
    
      3pkgname=trae-ide
    
      4pkgver=2.3.93439
    
      5pkgrel=1
    
      6pkgdesc="AI-powered IDE by ByteDance"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://www.trae.cn/"
    
      9license=('LicenseRef-Trae')
    
      10conflicts=('trae' 'trae-bin')
    
      11depends=('nss' 'alsa-lib' 'gtk3' 'at-spi2-core' 'libsecret' 'libxkbfile' 'zeromq')
    
      12optdepends=('libappindicator-gtk3: System tray support'
    
      13            'xdg-utils: Open URLs and files with default applications'
    
      14            'python: Python extension support'
    
      15            'nodejs: Node.js extension scripts')
    
      16options=('!strip' '!debug')
    
      17install=${pkgname}.install
    
      18source=("trae.sh" "trae.desktop")
    
      19source_x86_64=("Trae-linux-x64-${pkgver}-${pkgrel}.tar.gz::https://lf-cdn.trae.com.cn/obj/trae-com-cn/pkg/app/releases/stable/2.3.93439/linux/TRAE-linux-x64.tar.gz")
    
      20source_aarch64=("Trae-linux-arm64-${pkgver}-${pkgrel}.tar.gz::https://lf-cdn.trae.com.cn/obj/trae-com-cn/pkg/app/releases/stable/2.3.93439/linux/TRAE-linux-arm64.tar.gz")
    
      21b2sums=('2331b0d37fff8478ea37cbf9e5c2e70a59631aae6efb44741fc6c1a8dce65557098e9dffa8c30148ef27432802bec3d1eda279021421e5d3f979e80900662726'
    
      22            '656c5d6bea6ef15185e0d8ee0181276f6de3bfae8e66a2c65772a5f1354727952dd020dca057246139a2bab8f4805057fa2db367a6ba0a1b90d9ffd7fcab8412')
    
      23b2sums_x86_64=('bd22a253b100b0f062fe7bb96efd6afead437e1f78d18be9146c2cb0d2d87ab53b9dc689c7855410ac2ea2f9252d415d415e906614473a5895d713e6b230918b')
    
      24b2sums_aarch64=('67e549814e5d9ecc5429eef63deead3ad8264b94debd635e5b3e3ed14c3d6c3a723117ba0eb72d5525aa1302369542d2bd1fd437685f2399ecedb6fd0ac5a20e')
    
      25
    
      26package() {
    
      27    install -d "${pkgdir}/opt/trae"
    
      28
    
      29    for f in "${srcdir}"/*; do
    
      30        case "${f##*/}" in
    
      31            trae.sh|trae.desktop|*.tar.*) continue ;;
    
      32        esac
    
      33        cp -a "$f" "${pkgdir}/opt/trae/"
    
      34    done
    
      35
    
      36    # SUID sandbox
    
      37    chmod 4755 "${pkgdir}/opt/trae/chrome-sandbox"
    
      38
    
      39    # Launcher
    
      40    install -Dm755 "${srcdir}/trae.sh" "${pkgdir}/usr/bin/trae"
    
      41
    
      42    # Desktop entry
    
      43    install -Dm644 "${srcdir}/trae.desktop" "${pkgdir}/usr/share/applications/trae.desktop"
    
      44
    
      45    # Icon
    
      46    install -Dm644 "${pkgdir}/opt/trae/resources/app/resources/linux/code.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/trae.png"
    
      47
    
      48    # License
    
      49    install -Dm644 "${pkgdir}/opt/trae/resources/app/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      50    install -Dm644 "${pkgdir}/opt/trae/resources/app/ThirdPartyNotices.txt" "${pkgdir}/usr/share/licenses/${pkgname}/ThirdPartyNotices"
    
      51    install -Dm644 "${pkgdir}/opt/trae/LICENSES.chromium.html" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSES.chromium.html"
    
      52
    
      53    # Shell completions
    
      54    install -Dm644 "${pkgdir}/opt/trae/resources/completions/bash/trae" "${pkgdir}/usr/share/bash-completion/completions/trae"
    
      55    install -Dm644 "${pkgdir}/opt/trae/resources/completions/zsh/_trae" "${pkgdir}/usr/share/zsh/site-functions/_trae"
    
      56
    
      57    # Remove unnecessary files
    
      58    rm -rf "${pkgdir}/opt/trae/node_modules"
    
      59    find "${pkgdir}/opt/trae" -name "*.asc" -delete
    
      60    find "${pkgdir}/opt/trae" -name "*.bat" -delete
    
      61    find "${pkgdir}/opt/trae" -type d -name "rush-logs" -exec rm -rf {} +
    
      62
    
      63    # Remove bundled GCC runtime libraries (conflict with system gcc-libs, breaks ckg indexing)
    
      64    rm -fv "${pkgdir}/opt/trae/resources/app/modules/ckg/binary/libstdc++.so.6"
    
      65    rm -fv "${pkgdir}/opt/trae/resources/app/modules/ckg/binary/libgcc_s.so.1"
    
      66}
    
      67

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-03 12:09:28	Medium	3
2026-11-03 12:04:35	Medium	2