tsuzuri-git

LOW

maintainer shbernal 0 votes scanned 2026-10-30 11:55:28.915114

View on AUR

Why flagged

The package builds from the project's own Git repository, which is normal for AUR packages; the low severity is due to few votes and recent upload, not malicious content.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from the project's own Git repository, which is normal for AUR packages; the low severity is due to few votes and recent upload, not malicious content.

PKGBUILD

      1# Maintainer: shbernal <shbernal.01@gmail.com>
    
      2
    
      3_pkgname=tsuzuri
    
      4pkgname=${_pkgname}-git
    
      5pkgver=0.3.1.r1.gca1dc0e
    
      6pkgrel=1
    
      7pkgdesc='Block-based notebook for the terminal with plain Markdown files and Vim editing'
    
      8arch=('x86_64' 'aarch64')
    
      9url='https://github.com/jaisuriya-11/tsuzuri'
    
      10license=('MIT')
    
      11depends=('glibc')
    
      12makedepends=('git' 'go')
    
      13optdepends=('wl-clipboard: clipboard access on Wayland'
    
      14            'xclip: clipboard access on X11'
    
      15            'xdg-utils: open links'
    
      16            'zenity: file picker for attachments'
    
      17            'kdialog: file picker for attachments')
    
      18provides=("${_pkgname}")
    
      19conflicts=("${_pkgname}")
    
      20source=("${_pkgname}::git+${url}.git")
    
      21sha256sums=('SKIP')
    
      22
    
      23pkgver() {
    
      24  cd "${_pkgname}"
    
      25
    
      26  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      27}
    
      28
    
      29build() {
    
      30  cd "${_pkgname}"
    
      31
    
      32  export GOPATH="${srcdir}"
    
      33  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      34  export CGO_CFLAGS="${CFLAGS}"
    
      35  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      36  export CGO_LDFLAGS="${LDFLAGS}"
    
      37  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    
      38
    
      39  go build \
    
      40    -ldflags "-compressdwarf=false -linkmode external -X main.version=${pkgver}" \
    
      41    -o tsuzuri ./cmd/tsuzuri
    
      42}
    
      43
    
      44check() {
    
      45  cd "${_pkgname}"
    
      46
    
      47  export GOPATH="${srcdir}"
    
      48  export GOFLAGS="-trimpath -mod=readonly -modcacherw"
    
      49
    
      50  go test ./...
    
      51}
    
      52
    
      53package() {
    
      54  cd "${_pkgname}"
    
      55
    
      56  install -Dm755 tsuzuri "${pkgdir}/usr/bin/tsuzuri"
    
      57  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      58  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      59}
    
      60

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-30 11:55:28	Low	2