uncover-git

LOW

maintainer xa9e 0 votes scanned 2026-08-31 15:45:42.143005

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: xa9e <xa9e@protonmail.com>
    
      2pkgname=uncover-git
    
      3pkgver=1.2.1.r2.g8275048
    
      4pkgrel=1
    
      5pkgdesc='Quickly discover exposed hosts on the internet using multiple search engines (git version)'
    
      6arch=('x86_64' 'aarch64' 'armv7h' 'i686')
    
      7url='https://github.com/projectdiscovery/uncover'
    
      8license=('MIT')
    
      9depends=('glibc')
    
      10makedepends=('git' 'go')
    
      11provides=("uncover=${pkgver}")
    
      12conflicts=('uncover')
    
      13source=('uncover::git+https://github.com/projectdiscovery/uncover.git')
    
      14b2sums=('SKIP')
    
      15
    
      16pkgver() {
    
      17  cd uncover
    
      18  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      19}
    
      20
    
      21prepare() {
    
      22  export GOMODCACHE="${srcdir}/go-mod-cache"
    
      23
    
      24  cd uncover
    
      25  go mod download -modcacherw
    
      26  go mod verify
    
      27}
    
      28
    
      29build() {
    
      30  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      31  export CGO_CFLAGS="${CFLAGS}"
    
      32  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      33  export CGO_LDFLAGS="${LDFLAGS}"
    
      34  export GOCACHE="${srcdir}/go-cache"
    
      35  export GOMODCACHE="${srcdir}/go-mod-cache"
    
      36  export GOFLAGS='-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw'
    
      37
    
      38  cd uncover
    
      39  go build -v -o build/uncover ./cmd/uncover
    
      40}
    
      41
    
      42check() {
    
      43  export GOCACHE="${srcdir}/go-cache"
    
      44  export GOMODCACHE="${srcdir}/go-mod-cache"
    
      45  export GOFLAGS='-mod=readonly -modcacherw'
    
      46
    
      47  cd uncover
    
      48  go test ./...
    
      49}
    
      50
    
      51package() {
    
      52  cd uncover
    
      53  install -Dm755 build/uncover "${pkgdir}/usr/bin/uncover"
    
      54  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
    
      55  install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    
      56}
    
      57

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-31 15:45:42	Low	1