unsampled-piano

LOW

maintainer mgth 0 votes scanned 2026-10-25 01:41:32.578424

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Mathieu GRENET <mathieu@mgth.fr>
    
      2# Release package: built from the source of the v$pkgver tag. After
    
      3# tagging, refresh the checksum (updpkgsums) and .SRCINFO
    
      4# (makepkg --printsrcinfo > .SRCINFO).
    
      5
    
      6pkgname=unsampled-piano
    
      7pkgver=0.1.0
    
      8pkgrel=1
    
      9pkgdesc="Physically modelled piano, no samples: standalone player, CLAP and VST3 plugins"
    
      10arch=('x86_64' 'aarch64')
    
      11url="https://github.com/mgth/unsampled-piano"
    
      12license=('GPL-3.0-or-later')
    
      13# The window loads X11 or Wayland, xkbcommon and OpenGL at run time.
    
      14depends=('alsa-lib' 'gcc-libs' 'glibc' 'hicolor-icon-theme' 'libglvnd' 'libpipewire'
    
      15         'libx11' 'libxcursor' 'libxi' 'libxkbcommon' 'libxkbcommon-x11' 'wayland')
    
      16# jack: only its pkg-config file, for the build (jack-sys); libjack is
    
      17# loaded at run time.
    
      18makedepends=('cargo' 'clang' 'jack' 'pkgconf')
    
      19optdepends=('pipewire-jack: the player as a graph node with MIDI in and out (or jack2)')
    
      20# makepkg's LTO turns libspa's C wrappers into bitcode Rust's linker cannot read.
    
      21options=('!lto')
    
      22source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      23sha256sums=('a44638341471867f26ae1fb95f9dfe4d6bef96daf5c99defa821c10ebc15b1de')
    
      24
    
      25prepare() {
    
      26    cd "$pkgname-$pkgver"
    
      27    export RUSTUP_TOOLCHAIN=stable
    
      28    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      29}
    
      30
    
      31build() {
    
      32    cd "$pkgname-$pkgver"
    
      33    export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    
      34    # No build paths in the binaries (generated sources' locations).
    
      35    export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=$srcdir=/build"
    
      36    installer/linux/make-archive.sh --no-tar --frozen
    
      37}
    
      38
    
      39package() {
    
      40    cd "$pkgname-$pkgver"
    
      41    target/linux/$pkgname-$pkgver-linux-$CARCH/install.sh --destdir "$pkgdir" \
    
      42        --prefix /usr --clap-dir /usr/lib/clap --vst3-dir /usr/lib/vst3
    
      43}
    
      44

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-25 01:41:32	Low	1
2026-10-24 00:14:55	Clean	2
2026-10-23 17:38:05	Low	1