unsampled-piano-git

LOW

maintainer mgth 0 votes scanned 2026-10-25 01:41:32.578424

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Mathieu GRENET <mathieu@mgth.fr>
    
      2# Development package: the latest commit of main.
    
      3
    
      4pkgname=unsampled-piano-git
    
      5_name=unsampled-piano
    
      6pkgver=0.1.0.r90.gd773a16
    
      7pkgrel=1
    
      8pkgdesc="Physically modelled piano, no samples: standalone player, CLAP and VST3 plugins (development version)"
    
      9arch=('x86_64' 'aarch64')
    
      10url="https://github.com/mgth/unsampled-piano"
    
      11license=('GPL-3.0-or-later')
    
      12# The window loads X11 or Wayland, xkbcommon and OpenGL at run time.
    
      13depends=('alsa-lib' 'gcc-libs' 'glibc' 'hicolor-icon-theme' 'libglvnd' 'libpipewire'
    
      14         'libx11' 'libxcursor' 'libxi' 'libxkbcommon' 'libxkbcommon-x11' 'wayland')
    
      15# jack: only its pkg-config file, for the build (jack-sys); libjack is
    
      16# loaded at run time.
    
      17makedepends=('cargo' 'clang' 'git' 'jack' 'pkgconf')
    
      18optdepends=('pipewire-jack: the player as a graph node with MIDI in and out (or jack2)')
    
      19# makepkg's LTO turns libspa's C wrappers into bitcode Rust's linker cannot read.
    
      20options=('!lto')
    
      21provides=("$_name")
    
      22conflicts=("$_name")
    
      23source=("$_name::git+$url.git")
    
      24sha256sums=('SKIP')
    
      25
    
      26# Cargo version, commits since the start, commit.
    
      27pkgver() {
    
      28    cd "$_name"
    
      29    local version
    
      30    version=$(sed -n 's/^version = "\(.*\)"/\1/p' Cargo.toml | head -1)
    
      31    printf "%s.r%s.g%s" "$version" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      32}
    
      33
    
      34prepare() {
    
      35    cd "$_name"
    
      36    export RUSTUP_TOOLCHAIN=stable
    
      37    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      38}
    
      39
    
      40build() {
    
      41    cd "$_name"
    
      42    export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    
      43    # No build paths in the binaries (generated sources' locations).
    
      44    export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=$srcdir=/build"
    
      45    installer/linux/make-archive.sh --no-tar --frozen
    
      46}
    
      47
    
      48package() {
    
      49    cd "$_name"
    
      50    local version
    
      51    version=$(sed -n 's/^version = "\(.*\)"/\1/p' Cargo.toml | head -1)
    
      52    target/linux/$_name-$version-linux-$CARCH/install.sh --destdir "$pkgdir" \
    
      53        --prefix /usr --clap-dir /usr/lib/clap --vst3-dir /usr/lib/vst3
    
      54}
    
      55

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-25 01:41:32	Low	1
2026-10-24 00:14:55	Clean	2
2026-10-23 17:38:05	Low	1