untis-git

LOW

maintainer Felitendo 0 votes scanned 2026-09-28 11:20:45.263512

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Felitendo
    
      2# This PKGBUILD is updated automatically:
    
      3# https://github.com/Felitendo/PKGBUILDS
    
      4
    
      5pkgname=untis-git
    
      6pkgver=4.3.2.r31.g48ce032
    
      7pkgrel=1
    
      8pkgdesc="GTK4 + LibAdwaita client for WebUntis (git)"
    
      9arch=('any')
    
      10url="https://codeberg.org/ostfriese4/untis"
    
      11license=('GPL-3.0-or-later')
    
      12# main adds a QR code login: the camera comes through the portal (libportal)
    
      13# as a PipeWire stream, is shown with gtk4paintablesink and decoded with
    
      14# zxing-cpp's Python binding.
    
      15depends=('gtk4' 'libadwaita' 'webkitgtk-6.0' 'libsecret' 'python'
    
      16         'python-gobject' 'python-cairo' 'python-requests' 'python-pyotp'
    
      17         'python-pillow' 'python-zxing-cpp' 'libportal' 'gstreamer'
    
      18         'gst-plugins-base' 'gst-plugin-pipewire' 'gst-plugin-gtk4' 'glib2'
    
      19         'hicolor-icon-theme')
    
      20makedepends=('meson' 'ninja' 'glib2-devel' 'gettext' 'git')
    
      21provides=('untis')
    
      22conflicts=('untis' 'timetable')
    
      23source=("${pkgname}::git+https://codeberg.org/ostfriese4/untis.git")
    
      24sha256sums=('SKIP')
    
      25
    
      26pkgver() {
    
      27  cd "$pkgname"
    
      28  git describe --long --abbrev=7 --tags --match 'v[0-9]*' \
    
      29    | sed 's/^v//; s/\([^-]*-g\)/r\1/; s/-/./g'
    
      30}
    
      31
    
      32prepare() {
    
      33  # The About dialog reads the version from src/api.py, which upstream only
    
      34  # sets when it tags a release.
    
      35  sed -i "s/^version = \"[^\"]*\"/version = \"$pkgver\"/" "$pkgname/src/api.py"
    
      36}
    
      37
    
      38build() {
    
      39  meson setup build "$pkgname" \
    
      40    --prefix=/usr \
    
      41    --buildtype=release \
    
      42    --wrap-mode=nodownload
    
      43  meson compile -C build
    
      44}
    
      45
    
      46package() {
    
      47  meson install -C build --destdir "$pkgdir"
    
      48
    
      49  # generated by pacman hooks; shipping them would cause file conflicts
    
      50  rm -f "$pkgdir/usr/share/glib-2.0/schemas/gschemas.compiled" \
    
      51        "$pkgdir/usr/share/applications/mimeinfo.cache" \
    
      52        "$pkgdir/usr/share/icons/hicolor/icon-theme.cache"
    
      53}
    
      54

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-28 11:20:45	Low	1