vector-find

LOW

maintainer daanh 0 votes scanned 2026-10-28 19:50:31.752373

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Daan Hessen <daanhessen@notbadcompany.com>
    
      2pkgname=vector-find
    
      3pkgver=0.2.1
    
      4pkgrel=1
    
      5pkgdesc='Vector Find: fast GTK4 file manager with nvim-style keys, a terminal panel and Lua config'
    
      6arch=('x86_64' 'aarch64')
    
      7url='https://github.com/Not-Bad-Company/vector'
    
      8license=('MIT')
    
      9depends=('gtk4' 'gtksourceview5' 'vte4' 'glib2' 'pango' 'graphene' 'gdk-pixbuf2' 'glibc' 'libgcc' 'hicolor-icon-theme')
    
      10makedepends=('cargo')
    
      11provides=('vector-fm')
    
      12conflicts=('vector-fm')
    
      13replaces=('vector-fm')
    
      14optdepends=(
    
      15  'ttf-jetbrains-mono-nerd: the intended font and icons'
    
      16  'ffmpeg: video thumbnails, audio waveforms and media details'
    
      17  'poppler: pdf previews and details'
    
      18  'mpv: audio playback in the preview'
    
      19  'xdg-terminal-exec: open the terminal of your choice'
    
      20  'xdg-desktop-portal: use vector as the open/save dialog of other apps'
    
      21)
    
      22options=('!lto')
    
      23source=("vector-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
    
      24sha256sums=('a0e3b7e4e856319383b82e5032b5b81dc285bbd7f47168eb05c02a4ea7a1d6eb')
    
      25
    
      26prepare() {
    
      27  cd "vector-$pkgver"
    
      28  export RUSTUP_TOOLCHAIN=stable
    
      29  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      30}
    
      31
    
      32build() {
    
      33  cd "vector-$pkgver"
    
      34  export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    
      35  cargo build --frozen --release -p vector-find
    
      36}
    
      37
    
      38check() {
    
      39  cd "vector-$pkgver"
    
      40  export RUSTUP_TOOLCHAIN=stable
    
      41  VECTOR_NO_CLIPBOARD=1 cargo test --frozen -p vector-core -p vector-find
    
      42}
    
      43
    
      44package() {
    
      45  cd "vector-$pkgver"
    
      46  local id=io.github.not_bad_company.Vector
    
      47  install -Dm755 target/release/vector-find "$pkgdir/usr/bin/vector-find"
    
      48  install -Dm644 "data/$id.desktop" "$pkgdir/usr/share/applications/$id.desktop"
    
      49  install -Dm644 "data/$id.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/$id.svg"
    
      50  install -Dm644 data/vector.portal "$pkgdir/usr/share/xdg-desktop-portal/portals/vector.portal"
    
      51  sed 's|@BIN@|/usr/bin/vector-find|' data/org.freedesktop.impl.portal.desktop.vector.service.in \
    
      52    > org.freedesktop.impl.portal.desktop.vector.service
    
      53  install -Dm644 org.freedesktop.impl.portal.desktop.vector.service \
    
      54    -t "$pkgdir/usr/share/dbus-1/services"
    
      55  # org.freedesktop.FileManager1 is left out on purpose: it would take "show in folder" away
    
      56  # from whatever file manager is installed; the README explains how to opt in.
    
      57  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      58  install -Dm644 README.md data/org.freedesktop.FileManager1.service.in \
    
      59    -t "$pkgdir/usr/share/doc/$pkgname"
    
      60}
    
      61

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-28 19:50:31	Low	1
2026-10-28 17:50:30	Low	1