vicinae-private

LOW

maintainer nathanchere 0 votes scanned 2026-08-26 15:30:31.793073

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Nathan Chere <aur@nathanchere.com.au>
    
      2#
    
      3# Tries to stay mostly faithful to the stock Vicinae installer with a
    
      4# few privacy-focused amendmends:
    
      5# - removes telemetry services, UUID/state collection, settings, notices, and forget command
    
      6# - replaces update checking/installing with a no-op service (handled via AUR here anyway)
    
      7# - removes periodic currency-rate refresh (but maintains manual refresh)
    
      8# - preserves user-initiated networking and favicon providers
    
      9
    
      10pkgname=vicinae-private
    
      11_appname=vicinae
    
      12pkgver=0.27.0
    
      13_numenver=0.4.1
    
      14pkgrel=1
    
      15pkgdesc="Privacy-focused Vicinae build without telemetry or background network requests"
    
      16arch=('x86_64' 'aarch64')
    
      17url="https://github.com/vicinaehq/vicinae"
    
      18license=('GPL-3.0-only')
    
      19depends=(
    
      20  'nodejs'
    
      21  'qt6-base'
    
      22  'qt6-svg'
    
      23  'layer-shell-qt'
    
      24  'libqalculate'
    
      25  'qtkeychain-qt6'
    
      26  'qt6-declarative'
    
      27  'syntax-highlighting'
    
      28)
    
      29makedepends=(
    
      30  'cmake'
    
      31  'ninja'
    
      32  'npm'
    
      33  'glaze'
    
      34  'qt6-shadertools'
    
      35  'qt6-tools'
    
      36  'wayland-protocols'
    
      37  'cmark-gfm'
    
      38)
    
      39install="${_appname}.install"
    
      40provides=("${_appname}=${pkgver}")
    
      41conflicts=("${_appname}")
    
      42source=(
    
      43  "${_appname}-v${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
    
      44  "numen-v${_numenver}.tar.gz::https://github.com/vicinaehq/numen/archive/refs/tags/v${_numenver}.tar.gz"
    
      45  'disable-background-networking.patch'
    
      46  'vicinae.hook'
    
      47)
    
      48sha256sums=('9332752a6f2306d4a178ba5fd6ce149d21f64e90d0e0f853c6b3c335db9d3299'
    
      49            '0f758ba7a3306c214a5c1e7c5e35b3624f3a3d7361fdbfe36665d1088a9457f7'
    
      50            'a40171400f424e0f4b53cadc533abae02c5fabee3948b4380b34ea7700fd263e'
    
      51            '3cc96aa4cc38cf9bfd365feca8ee523e0c47c83a9d3f6f6fef43bed3ec0de209')
    
      52
    
      53prepare() {
    
      54  cd "${_appname}-${pkgver}"
    
      55  patch -Np1 -i "${srcdir}/disable-background-networking.patch"
    
      56}
    
      57
    
      58build() {
    
      59  cmake -S "${_appname}-${pkgver}" -B build -G Ninja \
    
      60    -DCMAKE_BUILD_TYPE=Release \
    
      61    -DCMAKE_INSTALL_PREFIX=/usr \
    
      62    -DFETCHCONTENT_SOURCE_DIR_NUMEN="${srcdir}/numen-${_numenver}" \
    
      63    -DUSE_SYSTEM_GLAZE=ON \
    
      64    -DVICINAE_GIT_TAG="v${pkgver}" \
    
      65    -DVICINAE_GIT_COMMIT_HASH=archive \
    
      66    -DVICINAE_PROVENANCE=aur-private
    
      67
    
      68  cmake --build build
    
      69}
    
      70
    
      71package() {
    
      72  DESTDIR="${pkgdir}" cmake --install build
    
      73
    
      74  rm -rf "${pkgdir}/usr/include/numen" \
    
      75         "${pkgdir}/usr/lib/cmake/numen" \
    
      76         "${pkgdir}/usr/lib/libnumen.a"
    
      77
    
      78  install -Dm644 "vicinae.hook" "${pkgdir}/usr/share/libalpm/hooks/vicinae.hook"
    
      79}
    
      80

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-26 15:30:31	Low	1