viper4linux-re

LOW

maintainer username227 0 votes scanned 2026-11-02 04:02:15.556644

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: username227 [gfrank227 [at] gmail [dot] com
    
      2# Stable release package built from the unified source archive.
    
      3
    
      4pkgname=viper4linux-re
    
      5pkgver=1.0.0
    
      6pkgrel=1
    
      7pkgdesc='ViPERDSP audio effects for PipeWire with a Qt6 interface'
    
      8arch=('x86_64')
    
      9url='https://github.com/username227/viper4linux-re'
    
      10license=('MIT' 'LicenseRef-ViPERDSP')
    
      11depends=('glibc' 'gcc-libs' 'qt6-base' 'pipewire' 'ladspa' 'python')
    
      12makedepends=('cmake' 'pkgconf')
    
      13conflicts=('viper4linux-re-git' 'viper4linux' 'viper4linux-git')
    
      14source=("https://github.com/username227/viper4linux-re/releases/download/v${pkgver}/viper4linux-re-${pkgver}-unified-source.tar.xz")
    
      15sha256sums=('5f22df6e4387bc73d80614c2a539e2fb668aa2a08a8a73c9db63ad8e49c5646d')
    
      16
    
      17prepare() {
    
      18    local tree="$srcdir/viper4linux-re-$pkgver"
    
      19    local dsp="$srcdir/ViPERDSP-patched"
    
      20    cp -a -- "$tree/third_party/ViPERDSP" "$dsp"
    
      21    VIPERDSP_SOURCE_DIR="$dsp" python3 "$tree/patches/fix_lufs_speed.py"
    
      22    VIPERDSP_SOURCE_DIR="$dsp" python3 "$tree/patches/preallocate_stereo_imager.py"
    
      23    VIPERDSP_SOURCE_DIR="$dsp" python3 "$tree/patches/preallocate_multiband_compressor.py"
    
      24}
    
      25
    
      26build() {
    
      27    cmake -S "$srcdir/viper4linux-re-$pkgver" -B "$srcdir/viper4linux-build" \
    
      28        -DCMAKE_BUILD_TYPE=Release \
    
      29        -DVIPERDSP_SOURCE_DIR="$srcdir/ViPERDSP-patched"
    
      30    cmake --build "$srcdir/viper4linux-build" --parallel "$(nproc)"
    
      31}
    
      32
    
      33check() {
    
      34    cd "$srcdir/viper4linux-re-$pkgver"
    
      35    bash tests/check-mock.sh
    
      36    python3 tests/check-launcher.py
    
      37    python3 tests/check-theme-contract.py
    
      38    python3 tests/check-ui-contract.py
    
      39    python3 tests/check-tray-contract.py
    
      40    python3 tests/check-named-presets-contract.py
    
      41    python3 tests/check-preset-reset-contract.py
    
      42    nm -D "$srcdir/viper4linux-build/viper_dsp_ladspa.so" | grep -Eq ' [TW] ladspa_descriptor$'
    
      43}
    
      44
    
      45package() {
    
      46    local tree="$srcdir/viper4linux-re-$pkgver"
    
      47    local built="$srcdir/viper4linux-build"
    
      48
    
      49# Executables
    
      50    install -Dm755 "$built/viper-gui" "$pkgdir/usr/bin/viper4linux-gui"
    
      51    install -Dm755 "$built/viper-ctl" "$pkgdir/usr/bin/viper4linux-ctl"
    
      52
    
      53# Libraries
    
      54    install -Dm755 "$built/viper_dsp_ladspa.so" "$pkgdir/usr/lib/ladspa/viper_dsp_ladspa.so"
    
      55
    
      56# Launchers
    
      57    install -Dm644 "$tree/src/viper_launcher.py" "$pkgdir/usr/lib/viper4linux/viper_launcher.py"
    
      58    install -Dm755 "$tree/packaging/arch/start-backend" "$pkgdir/usr/lib/viper4linux/start-backend"
    
      59    install -Dm755 "$tree/packaging/arch/viper4linux" "$pkgdir/usr/bin/viper4linux"
    
      60
    
      61# Pipewire Routing Configuration
    
      62    install -Dm644 "$tree/routing-config/filter-chain.conf.d/99-viper-smart.conf" "$pkgdir/usr/share/viper4linux/routing-config/filter-chain.conf.d/99-viper-smart.conf"
    
      63
    
      64# Desktop File
    
      65    install -Dm644 "$tree/packaging/arch/viper4linux.desktop" "$pkgdir/usr/share/applications/viper4linux.desktop"
    
      66
    
      67# Icons
    
      68    install -Dm644 "$tree/resources/viper4linux-blue.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/viper4linux.png"
    
      69    install -Dm644 "$tree/resources/viper4linux-blue.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/viper4linux.svg"
    
      70
    
      71# Man Pages
    
      72    install -Dm644 "$tree/man/viper4linux.1" "$pkgdir/usr/share/man/man1/viper4linux.1"
    
      73    install -Dm644 "$tree/man/viper4linux-ctl.1" "$pkgdir/usr/share/man/man1/viper4linux-ctl.1"
    
      74
    
      75# License and Third-Party Notices
    
      76    install -Dm644 "$tree/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      77    install -Dm644 "$tree/THIRD-PARTY-NOTICES.md" "$pkgdir/usr/share/licenses/$pkgname/ViPERDSP-NOTICE.md"
    
      78
    
      79# Documentation
    
      80    install -Dm644 "$tree/README.md" "$pkgdir/usr/share/doc/viper4linux/README.md"
    
      81    install -d "$pkgdir/usr/share/doc/viper4linux/docs"
    
      82    cp -a "$tree/docs/." "$pkgdir/usr/share/doc/viper4linux/docs/"
    
      83}
    
      84

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-02 04:02:15	Low	1