vizard-bin

MEDIUM

maintainer BoostCookie 0 votes scanned 2026-10-17 00:21:55.226236

View on AUR

Why flagged

Prebuilt Unity binary downloaded from a personal/project-adjacent host (hanspeterschaub.info) rather than official release infrastructure like GitHub releases; the zip is unversioned and replaced in-place upstream, meaning the checksum can go stale silently, making the binary unverifiable and trivially swappable by the host owner.

Triggered rules

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:18 source=("Vizard_Linux-$pkgver.zip::https://hanspeterschaub.info/bskFiles/Vizard_Linux.zip"

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Medium AI review llm_review

An AI model (anthropic/claude-sonnet-4.6) reviewed this and agrees it is MEDIUM (confidence 70%): Prebuilt Unity binary downloaded from a personal/project-adjacent host (hanspeterschaub.info) rather than official release infrastructure like GitHub releases; the zip is unversioned and replaced in-place upstream, meaning the checksum can go stale silently, making the binary unverifiable and trivially swappable by the host owner.

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: Stefan Gehr <stefan@gehr.xyz>
    
      2pkgname=vizard-bin
    
      3_pkgname=vizard
    
      4pkgver=2.4.0
    
      5pkgrel=1
    
      6pkgdesc="Unity-based 3D visualization companion for the Basilisk spacecraft simulation framework (prebuilt binary)"
    
      7arch=('x86_64')
    
      8url="https://github.com/AVSLab/vizard"
    
      9license=('ISC')
    
      10depends=('glibc' 'gcc-libs' 'gtk3' 'libgl' 'libx11')
    
      11optdepends=('vulkan-icd-loader: Vulkan rendering'
    
      12            'basilisk: simulation framework that produces the data Vizard displays')
    
      13provides=("$_pkgname")
    
      14conflicts=("$_pkgname")
    
      15# Unity players break if stripped
    
      16options=('!strip' '!debug')
    
      17noextract=("Vizard_Linux-$pkgver.zip")
    
      18source=("Vizard_Linux-$pkgver.zip::https://hanspeterschaub.info/bskFiles/Vizard_Linux.zip"
    
      19        "LICENSE-$pkgver::https://raw.githubusercontent.com/AVSLab/vizard/master/LICENSE")
    
      20# Upstream's zip is unversioned and replaced in place; run `updpkgsums`
    
      21# for each release and expect hashes to go stale if upstream re-uploads.
    
      22sha256sums=('c2482c11c4ae41eea810a44a15330623ca3bc300adab6aa8536cf9676b1e1fb0'
    
      23            'd80ca16ce044732ac4ebdd36052eb45d44e32ae0d7baaec803c8feed5cfa3657')
    
      24
    
      25prepare() {
    
      26  mkdir -p "$srcdir/$_pkgname"
    
      27  # Extract only the app directory, skipping __MACOSX/ resource-fork junk
    
      28  bsdtar -xf "Vizard_Linux-$pkgver.zip" -C "$srcdir/$_pkgname" 'Vizard_Linux'
    
      29  find "$srcdir/$_pkgname" -name '.DS_Store' -delete
    
      30}
    
      31
    
      32package() {
    
      33  local _exe="Vizard.$CARCH"
    
      34
    
      35  install -d "$pkgdir/usr/lib/$_pkgname"
    
      36  cp -a "$srcdir/$_pkgname/Vizard_Linux/." "$pkgdir/usr/lib/$_pkgname/"
    
      37  chmod -R u=rwX,go=rX "$pkgdir/usr/lib/$_pkgname"
    
      38  chmod 755 "$pkgdir/usr/lib/$_pkgname/$_exe"
    
      39
    
      40  # Launcher. The bundled native file browser has no Wayland support,
    
      41  # so default GTK to X11 (override by exporting GDK_BACKEND yourself).
    
      42  install -d "$pkgdir/usr/bin"
    
      43  cat > "$pkgdir/usr/bin/vizard" <<EOF
    
      44#!/bin/sh
    
      45export GDK_BACKEND="\${GDK_BACKEND:-x11}"
    
      46exec /usr/lib/$_pkgname/$_exe "\$@"
    
      47EOF
    
      48  chmod 755 "$pkgdir/usr/bin/vizard"
    
      49
    
      50  install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/vizard.desktop" <<EOF
    
      51[Desktop Entry]
    
      52Type=Application
    
      53Name=Vizard
    
      54Comment=Basilisk spacecraft simulation visualization
    
      55Exec=vizard
    
      56Icon=applications-science
    
      57Terminal=false
    
      58Categories=Science;Education;
    
      59EOF
    
      60
    
      61  install -Dm644 "$srcdir/LICENSE-$pkgver" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      62}
    
      63

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-17 00:21:55	Medium	3
2026-10-16 00:12:47	Medium	3
2026-10-15 00:28:05	Medium	3
2026-10-14 00:06:47	Medium	3
2026-10-13 00:23:45	Medium	3
2026-10-12 00:18:51	Medium	3
2026-10-11 00:26:05	Medium	3
2026-10-10 10:16:51	Medium	3
2026-10-10 10:13:47	Medium	3