voicenux

LOW

maintainer Felitendo 0 votes scanned 2026-10-19 07:24:05.635861

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Felitendo
    
      2# This PKGBUILD is updated automatically:
    
      3# https://github.com/Felitendo/PKGBUILDS
    
      4
    
      5pkgname=voicenux
    
      6pkgver=0.1.0
    
      7pkgrel=1
    
      8pkgdesc="VoiceMod for Linux. Real-time voice changer and soundboard for PipeWire"
    
      9arch=('x86_64')
    
      10url="https://github.com/voicenux/voicenux"
    
      11# BSD: the program. MIT: the Fluent Emoji pictures, ISC: the Lucide icons,
    
      12# CC0: the background sounds. All of them are built into the binary.
    
      13license=('BSD-3-Clause' 'MIT' 'ISC' 'CC0-1.0')
    
      14# Upstream wants PipeWire and WirePlumber running, not only the library.
    
      15depends=('gtk4' 'libadwaita' 'libpipewire' 'pipewire' 'wireplumber' 'glib2'
    
      16         'cairo' 'pango' 'graphene' 'libgcc' 'glibc' 'hicolor-icon-theme')
    
      17# clang: bindgen, for the PipeWire headers
    
      18makedepends=('rust' 'clang')
    
      19optdepends=('xdg-desktop-portal: global shortcuts')
    
      20# !lto: makepkg's -flto=auto in CFLAGS turns ring's assembly (the TLS of
    
      21# the downloads) into bitcode that links to nothing. Cargo's own LTO is
    
      22# set in upstream's release profile.
    
      23options=('!lto')
    
      24source=("${pkgname}-${pkgver}.tar.gz::https://github.com/voicenux/voicenux/archive/refs/tags/v${pkgver}.tar.gz")
    
      25sha256sums=('93180b3e7823f1da7dece65b4b360f11b8d5934d00c34dd9f68951d3572dce23')
    
      26
    
      27prepare() {
    
      28  cd "${pkgname}-${pkgver}"
    
      29
    
      30  export RUSTUP_TOOLCHAIN=stable
    
      31  cargo fetch --locked --target "$(rustc -vV | sed -n 's/^host: //p')"
    
      32}
    
      33
    
      34build() {
    
      35  cd "${pkgname}-${pkgver}"
    
      36
    
      37  export RUSTUP_TOOLCHAIN=stable
    
      38  export CARGO_TARGET_DIR=target
    
      39  cargo build --release --frozen
    
      40}
    
      41
    
      42package() {
    
      43  cd "${pkgname}-${pkgver}"
    
      44
    
      45  make install DESTDIR="$pkgdir" PREFIX=/usr
    
      46  # the emoji licence, which `make install` leaves out
    
      47  install -Dm644 data/icons/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE.emoji"
    
      48}
    
      49

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-19 07:24:05	Low	1