vuurmuur

MEDIUM

maintainer gilcu3 26 votes scanned 2026-09-05 09:59:47.702300

View on AUR

Why flagged

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

Triggered rules

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:30 source=(https://www.vuurmuur.org/releases/$pkgver/${pkgname}-$pkgver.tar.gz

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: gilcu3
    
      2
    
      3# Previous Maintainers
    
      4# Piotr Rogoża <rogoza dot piotr at gmail dot com>
    
      5
    
      6# Contributor: skydrome <skydrome@i2pmail.org>
    
      7# Contributor: Valere Monseur <valere_monseur@hotmail.com>
    
      8# Contributor: Phillip Smith <fukawi2@NO-SPAM.gmail.com>
    
      9# Contributor: (asper, noob
    
      10# Contributor: ratamahata
    
      11
    
      12pkgname=vuurmuur
    
      13pkgver=0.8.2
    
      14pkgrel=1
    
      15pkgdesc='powerful front-end for iptables aimed at system-administrators who need a decent firewall, but dont have netfilter specific knowledge'
    
      16arch=('i686' 'x86_64' 'armv7h' 'aarch64')
    
      17url='http://www.vuurmuur.org'
    
      18license=('GPL-2.0-or-later')
    
      19install='vuurmuur.install'
    
      20depends=(libnetfilter_log libnetfilter_conntrack libmnl iptables ncurses)
    
      21optdepends=('conntrack-tools: for connection tracking'
    
      22            'iproute2: for traffic shapping'
    
      23            'iptrafvol: for traffic volume logging')
    
      24conflicts=()
    
      25backup=('etc/vuurmuur/config.conf'
    
      26        'etc/vuurmuur/modules.conf'
    
      27        'etc/vuurmuur/vuurmuur_conf.conf'
    
      28        'etc/vuurmuur/plugins/textdir.conf'
    
      29)
    
      30source=(https://www.vuurmuur.org/releases/$pkgver/${pkgname}-$pkgver.tar.gz
    
      31        modules.conf
    
      32        vuurmuur.service
    
      33        vuurmuur.script)
    
      34sha256sums=('6388c4df83b327603f632e15b3201c297247f91d8adcc49172675738b935a5b3'
    
      35            'a18d4093075f8e0a24f902780b04d03116be8c057b139a7502d8517009bd65e0'
    
      36            '1bf559e49ac64cdf6bff9b003adbe97af1b222d59ec49242545cf13daee07a24'
    
      37            'de4cee0e33d3431c985289d8de2844eeb1b1e614e69b7e3b1d6c99e8cda3aa4f')
    
      38
    
      39build() {
    
      40    cd ${pkgname}-${pkgver}
    
      41
    
      42    ./configure --prefix=/usr --sysconfdir=/etc
    
      43    make
    
      44}
    
      45
    
      46package() {
    
      47    cd ${pkgname}-${pkgver}
    
      48
    
      49    make DESTDIR="$pkgdir" install
    
      50
    
      51    # make directory structure
    
      52    install -dm700 "$pkgdir"/etc/$pkgname
    
      53    install -dm700 "$pkgdir"/etc/${pkgname}/plugins
    
      54    install -dm755 "$pkgdir"/usr/share/$pkgname/textdir/{interfaces,services,zones,rules}
    
      55    install -dm700 "$pkgdir"/var/log/$pkgname
    
      56
    
      57    # install systemd's files
    
      58    install -Dm755 ../vuurmuur.script "$pkgdir"/usr/lib/systemd/scripts/vuurmuur
    
      59    install -Dm644 ../vuurmuur.service "$pkgdir"/usr/lib/systemd/system/vuurmuur.service
    
      60
    
      61    # install configuration
    
      62    install -Dm600 "$pkgdir"/usr/share/vuurmuur/config/config.conf.sample \
    
      63                    "$pkgdir"/etc/${pkgname}/config.conf
    
      64    install -Dm600 ../modules.conf "$pkgdir"/etc/${pkgname}/modules.conf
    
      65    install -Dm600 "$pkgdir"/usr/share/vuurmuur/config/vuurmuur_conf.conf.sample \
    
      66                    "$pkgdir"/etc/${pkgname}/${pkgname}_conf.conf
    
      67
    
      68    sed -i "$pkgdir"/etc/${pkgname}/config.conf \
    
      69        -e 's|"/sbin/tc|"/usr/bin/tc|' \
    
      70        -e 's|"/sbin/ip6tables|"/usr/bin/ip6tables|' \
    
      71        -e 's|"/sbin/iptables|"/usr/bin/iptables|' \
    
      72        -e 's|"/sbin/ip6tables-restore|"/usr/bin/ip6tables-restore|' \
    
      73        -e 's|"/sbin/iptables-restore|"/usr/bin/iptables-restore|'
    
      74
    
      75
    
      76    echo "LOCATION=\"/etc/${pkgname}/textdir\"" > "$pkgdir"/etc/${pkgname}/plugins/textdir.conf
    
      77
    
      78    # default firewall setup in /usr/share
    
      79    touch "$pkgdir"/usr/share/${pkgname}/textdir/rules/rules.conf
    
      80    touch "$pkgdir"/usr/share/${pkgname}/textdir/rules/blocklist.conf
    
      81
    
      82#    cp -R zones/*   "$pkgdir"/usr/share/${pkgname}/textdir/zones/
    
      83    mv    "$pkgdir"/usr/share/${pkgname}/services/* "$pkgdir"/usr/share/${pkgname}/textdir/services/
    
      84}
    
      85

Changes since previous scan

--- PKGBUILD @ 2026-06-19 19:07
+++ PKGBUILD @ 2026-09-05 09:59
@@ -10,14 +10,14 @@
 # Contributor: ratamahata
 
 pkgname=vuurmuur
-pkgver=0.8.1
+pkgver=0.8.2
 pkgrel=1
 pkgdesc='powerful front-end for iptables aimed at system-administrators who need a decent firewall, but dont have netfilter specific knowledge'
 arch=('i686' 'x86_64' 'armv7h' 'aarch64')
 url='http://www.vuurmuur.org'
-license=('GPL')
+license=('GPL-2.0-or-later')
 install='vuurmuur.install'
-depends=(libnetfilter_log iptables ncurses libjpeg)
+depends=(libnetfilter_log libnetfilter_conntrack libmnl iptables ncurses)
 optdepends=('conntrack-tools: for connection tracking'
             'iproute2: for traffic shapping'
             'iptrafvol: for traffic volume logging')
@@ -29,12 +29,10 @@
 )
 source=(https://www.vuurmuur.org/releases/$pkgver/${pkgname}-$pkgver.tar.gz
         modules.conf
-        vuurmuur.rc
         vuurmuur.service
         vuurmuur.script)
-sha256sums=('4b5318fb5693308d8fae9a3bf7d20a3c470055900db2d1c4819ed6046d404899'
+sha256sums=('6388c4df83b327603f632e15b3201c297247f91d8adcc49172675738b935a5b3'
             'a18d4093075f8e0a24f902780b04d03116be8c057b139a7502d8517009bd65e0'
-            'f1b49c9e1480f9d37ef2df779f725f926552f8713f7aacfc49e0b359e10f27a5'
             '1bf559e49ac64cdf6bff9b003adbe97af1b222d59ec49242545cf13daee07a24'
             'de4cee0e33d3431c985289d8de2844eeb1b1e614e69b7e3b1d6c99e8cda3aa4f')
 
@@ -55,9 +53,6 @@
     install -dm700 "$pkgdir"/etc/${pkgname}/plugins
     install -dm755 "$pkgdir"/usr/share/$pkgname/textdir/{interfaces,services,zones,rules}
     install -dm700 "$pkgdir"/var/log/$pkgname
-
-    # install daemon and log
-    install -Dm755 ../vuurmuur.rc "$pkgdir"/etc/rc.d/$pkgname
 
     # install systemd's files
     install -Dm755 ../vuurmuur.script "$pkgdir"/usr/lib/systemd/scripts/vuurmuur

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-05 09:59:47	Medium	1
2026-06-19 19:07:35	Clean	2
2026-06-19 18:54:17	Clean	2
2026-06-18 16:11:54	Medium	1