wallhelper-git

CLEAN

maintainer jaehho 0 votes scanned 2026-09-10 00:22:44.768965

View on AUR

Triggered rules

Clean AI review downgraded a static finding llm_review

The static rules flagged this LOW, but an AI model (qwen/qwen3-235b-a22b-2507) reviewed the full PKGBUILD and judged it CLEAN (confidence 95%): The package builds from a public Git repository hosted on GitHub, uses standard Python build tools, and installs only the project's own code and metadata; the flagged low-vote and recent upload are not indicators of inherent risk.

1 higher static finding superseded - not the current verdict (shown for transparency)

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: Jaeho Cho <jaeho2025@gmail.com>
    
      2pkgname=wallhelper-git
    
      3_pkgname=wallhelper
    
      4pkgver=1.0.0
    
      5pkgrel=1
    
      6pkgdesc="One new photograph a day, and the ones you kept"
    
      7arch=('any')
    
      8url="https://github.com/jaehho/wallhelper"
    
      9license=('MIT')
    
      10# python-gobject, gtk4 and libadwaita are only needed by `wallhelper gui`; the
    
      11# fetch that runs from a systemd timer uses nothing but the standard library.
    
      12depends=('python' 'python-gobject' 'gtk4' 'libadwaita')
    
      13optdepends=('hyprpaper: setting the wallpaper under Hyprland'
    
      14            'libnotify: desktop notifications'
    
      15            'xdg-desktop-portal: opening source pages and signup pages')
    
      16makedepends=('git' 'python-build' 'python-installer' 'python-setuptools'
    
      17             'python-wheel')
    
      18source=("git+$url.git")
    
      19sha256sums=('SKIP')
    
      20
    
      21pkgver() {
    
      22	cd "$_pkgname"
    
      23	local desc
    
      24	if desc=$(git describe --long --tags --abbrev=7 2>/dev/null); then
    
      25		# tagged: v1.2.3-4-gabcdef -> 1.2.3.r4.gabcdef
    
      26		printf '%s' "$desc" | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
    
      27	else
    
      28		# no tags yet: 1.0.0.r<commits>.g<short>
    
      29		printf '1.0.0.r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      30	fi
    
      31}
    
      32
    
      33build() {
    
      34	cd "$_pkgname"
    
      35	python -m build --wheel --no-isolation
    
      36}
    
      37
    
      38check() {
    
      39	cd "$_pkgname"
    
      40	# The suite deletes files, so it insists on being pointed at a scratch
    
      41	# collection; -t . is what imports the tests package that does the pointing.
    
      42	python -m unittest discover -s tests -t .
    
      43}
    
      44
    
      45package() {
    
      46	cd "$_pkgname"
    
      47	python -m installer --destdir="$pkgdir" dist/*.whl
    
      48	install -Dm644 packaging/dev.jaeho.Wallhelper.desktop \
    
      49		"$pkgdir/usr/share/applications/dev.jaeho.Wallhelper.desktop"
    
      50	install -Dm644 README.md "$pkgdir/usr/share/doc/$_pkgname/README.md"
    
      51	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      52}
    
      53

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-10 00:22:44	Clean	2
2026-09-09 23:20:11	Low	1