wayrcursor-git

LOW

maintainer surfer 0 votes scanned 2026-10-19 15:25:12.467407

View on AUR

Why flagged

The package builds from source via Git, uses standard Rust tooling, and installs only the resulting binary and documentation; the low severity is due to few votes and recent upload, not malicious content.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package builds from source via Git, uses standard Rust tooling, and installs only the resulting binary and documentation; the low severity is due to few votes and recent upload, not malicious content.

PKGBUILD

      1# Maintainer: Casper <casper@codemu.ch>
    
      2pkgname=wayrcursor-git
    
      3_pkgname=wayrcursor
    
      4pkgver=1.0.0.r32.gafa6dfc
    
      5pkgrel=1
    
      6pkgdesc='Shows where the cursor is on Wayland'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/cmvanb/wayrcursor'
    
      9license=('GPL-3.0-or-later')
    
      10depends=('glibc' 'libgcc' 'libglvnd' 'wayland')
    
      11makedepends=('cargo' 'git')
    
      12provides=("$_pkgname")
    
      13conflicts=("$_pkgname")
    
      14source=("git+$url.git")
    
      15sha256sums=('SKIP')
    
      16
    
      17pkgver() {
    
      18  cd "$_pkgname"
    
      19  printf '%s.r%s.g%s' \
    
      20    "$(grep -m1 '^version' Cargo.toml | cut -d'"' -f2)" \
    
      21    "$(git rev-list --count HEAD)" \
    
      22    "$(git rev-parse --short=7 HEAD)"
    
      23}
    
      24
    
      25prepare() {
    
      26  cd "$_pkgname"
    
      27  export RUSTUP_TOOLCHAIN=stable
    
      28  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
    
      29}
    
      30
    
      31build() {
    
      32  cd "$_pkgname"
    
      33  export RUSTUP_TOOLCHAIN=stable
    
      34  export CARGO_TARGET_DIR=target
    
      35  cargo build --frozen --release
    
      36}
    
      37
    
      38check() {
    
      39  cd "$_pkgname"
    
      40  export RUSTUP_TOOLCHAIN=stable
    
      41  cargo test --frozen
    
      42}
    
      43
    
      44package() {
    
      45  cd "$_pkgname"
    
      46  install -Dm755 target/release/$_pkgname "$pkgdir/usr/bin/$_pkgname"
    
      47  sed 's|@BINDIR@|/usr/bin|' dist/$_pkgname.service.in |
    
      48    install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/user/$_pkgname.service"
    
      49  install -Dm644 dist/config.toml "$pkgdir/usr/share/doc/$_pkgname/config.toml"
    
      50  install -Dm644 README.md "$pkgdir/usr/share/doc/$_pkgname/README.md"
    
      51}
    
      52

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-19 15:25:12	Low	2