webdav

LOW

maintainer agony4001 0 votes scanned 2026-10-27 07:47:02.942332

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=webdav
    
      4pkgver=5.17.2
    
      5pkgrel=1
    
      6pkgdesc='Standalone WebDAV server'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/hacdias/webdav'
    
      9license=('MIT')
    
      10depends=('glibc')
    
      11makedepends=('go')
    
      12backup=('etc/webdav/config.yml')
    
      13source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
    
      14        'config.yml'
    
      15        'webdav.service'
    
      16        'webdav.sysusers'
    
      17        'webdav.tmpfiles')
    
      18sha256sums=('d4d84822f0ceb5255cf7b360e33218b3ff2f0e54c2167c39a392565561a11f96'
    
      19            'd178253eaf9dee6faad783ec9a1d61c0babca6ddced3216ee81957e05873b201'
    
      20            'f775c6ec0eb47472b7d7a13a10508b5aedf2fa7a92aeb4a8492484e64dd64b56'
    
      21            '2e6ceac8a2cbdd85ceb6ebbb7cae7d1ad00b14fc8a7e131da9c7ef573f3246e0'
    
      22            'f236c800ceb469bbb5fe003866f51881f07637ad940a39bf375804e725996642')
    
      23
    
      24prepare() {
    
      25  cd "${pkgname}-${pkgver}"
    
      26  export GOPATH="${srcdir}/gopath"
    
      27  go mod download -x -modcacherw
    
      28}
    
      29
    
      30build() {
    
      31  cd "${pkgname}-${pkgver}"
    
      32  export GOPATH="${srcdir}/gopath"
    
      33  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      34  export CGO_CFLAGS="${CFLAGS}"
    
      35  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      36  export CGO_LDFLAGS="${LDFLAGS}"
    
      37  export GOFLAGS='-buildmode=pie -trimpath -buildvcs=false -mod=readonly -modcacherw'
    
      38  go build -v -ldflags="-linkmode=external -X github.com/hacdias/webdav/v5/cmd.version=${pkgver}" -o webdav .
    
      39  for shell in bash fish zsh; do
    
      40    ./webdav completion "${shell}" > "completion.${shell}"
    
      41  done
    
      42}
    
      43
    
      44package() {
    
      45  install -Dm640 config.yml "${pkgdir}/etc/webdav/config.yml"
    
      46  install -Dm644 webdav.service -t "${pkgdir}/usr/lib/systemd/system"
    
      47  install -Dm644 webdav.sysusers "${pkgdir}/usr/lib/sysusers.d/webdav.conf"
    
      48  install -Dm644 webdav.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/webdav.conf"
    
      49  cd "${pkgname}-${pkgver}"
    
      50  install -Dm755 webdav -t "${pkgdir}/usr/bin"
    
      51  install -Dm644 completion.bash "${pkgdir}/usr/share/bash-completion/completions/webdav"
    
      52  install -Dm644 completion.fish "${pkgdir}/usr/share/fish/vendor_completions.d/webdav.fish"
    
      53  install -Dm644 completion.zsh "${pkgdir}/usr/share/zsh/site-functions/_webdav"
    
      54  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      55}
    
      56

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-27 07:47:02	Low	1