webdav-git

LOW

maintainer agony4001 0 votes scanned 2026-10-27 11:47:37.152749

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: agony <27015 at riseup dot net>
    
      2
    
      3pkgname=webdav-git
    
      4pkgver=r292.0ca5bbb
    
      5pkgrel=1
    
      6pkgdesc='Standalone WebDAV server (git version)'
    
      7arch=('x86_64' 'aarch64')
    
      8url='https://github.com/hacdias/webdav'
    
      9license=('MIT')
    
      10depends=('glibc')
    
      11makedepends=('git' 'go')
    
      12provides=('webdav')
    
      13conflicts=('webdav')
    
      14backup=('etc/webdav/config.yml')
    
      15source=("webdav::git+${url}.git"
    
      16        'config.yml'
    
      17        'webdav.service'
    
      18        'webdav.sysusers'
    
      19        'webdav.tmpfiles')
    
      20sha256sums=('SKIP'
    
      21            'd178253eaf9dee6faad783ec9a1d61c0babca6ddced3216ee81957e05873b201'
    
      22            'f775c6ec0eb47472b7d7a13a10508b5aedf2fa7a92aeb4a8492484e64dd64b56'
    
      23            '2e6ceac8a2cbdd85ceb6ebbb7cae7d1ad00b14fc8a7e131da9c7ef573f3246e0'
    
      24            'f236c800ceb469bbb5fe003866f51881f07637ad940a39bf375804e725996642')
    
      25
    
      26pkgver() {
    
      27  cd webdav
    
      28  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    
      29}
    
      30
    
      31prepare() {
    
      32  cd webdav
    
      33  export GOPATH="${srcdir}/gopath"
    
      34  go mod download -x -modcacherw
    
      35}
    
      36
    
      37build() {
    
      38  cd webdav
    
      39  export GOPATH="${srcdir}/gopath"
    
      40  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      41  export CGO_CFLAGS="${CFLAGS}"
    
      42  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      43  export CGO_LDFLAGS="${LDFLAGS}"
    
      44  export GOFLAGS='-buildmode=pie -trimpath -buildvcs=false -mod=readonly -modcacherw'
    
      45  local version
    
      46  version=$(git describe --tags | sed 's/^v//')
    
      47  go build -v -ldflags="-linkmode=external -X github.com/hacdias/webdav/v5/cmd.version=${version}" -o webdav .
    
      48  for shell in bash fish zsh; do
    
      49    ./webdav completion "${shell}" > "completion.${shell}"
    
      50  done
    
      51}
    
      52
    
      53package() {
    
      54  install -Dm640 config.yml "${pkgdir}/etc/webdav/config.yml"
    
      55  install -Dm644 webdav.service -t "${pkgdir}/usr/lib/systemd/system"
    
      56  install -Dm644 webdav.sysusers "${pkgdir}/usr/lib/sysusers.d/webdav.conf"
    
      57  install -Dm644 webdav.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/webdav.conf"
    
      58  cd webdav
    
      59  install -Dm755 webdav -t "${pkgdir}/usr/bin"
    
      60  install -Dm644 completion.bash "${pkgdir}/usr/share/bash-completion/completions/webdav"
    
      61  install -Dm644 completion.fish "${pkgdir}/usr/share/fish/vendor_completions.d/webdav.fish"
    
      62  install -Dm644 completion.zsh "${pkgdir}/usr/share/zsh/site-functions/_webdav"
    
      63  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
    
      64}
    
      65

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-27 11:47:37	Low	1