wingdrive-nightly

LOW

maintainer bernardopg 0 votes scanned 2026-11-05 20:10:15.251681

View on AUR

Why flagged

The package downloads a prebuilt AppImage from the project's official GitHub releases, extracts it, and installs components while relying mostly on system libraries; the source is trustworthy and the build process is transparent, though the AppImage is not independently reproducible.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-2507) reviewed this and agrees it is LOW (confidence 95%): The package downloads a prebuilt AppImage from the project's official GitHub releases, extracts it, and installs components while relying mostly on system libraries; the source is trustworthy and the build process is transparent, though the AppImage is not independently reproducible.

PKGBUILD

      1# Maintainer: Bernardo Gomes <bernardopg@users.noreply.github.com>
    
      2pkgname=wingdrive-nightly
    
      3pkgver=3.0.0
    
      4pkgrel=1
    
      5pkgdesc='WingDrive desktop file manager, every release including alpha, beta and rc'
    
      6arch=('x86_64')
    
      7url='https://github.com/bernardopg/wingdrive'
    
      8license=('Apache-2.0' 'GPL-3.0-only')
    
      9depends=('glibc' 'libgcc' 'glib2' 'gtk3' 'webkit2gtk-4.1' 'libsoup3' 'cairo' 'gdk-pixbuf2' 'dbus' 'libheif' 'libva' 'xdg-utils' 'libayatana-appindicator')
    
      10optdepends=('gst-plugins-good: audio and video playback in previews'
    
      11            'gvfs: network locations (SFTP, FTP, WebDAV) in the sidebar'
    
      12            'gvfs-mtp: Android phones over MTP'
    
      13            'gvfs-smb: Windows and Samba shares'
    
      14            'gvfs-gphoto2: cameras'
    
      15            'ffmpeg: video thumbnails in folders that are not indexed'
    
      16            'poppler: PDF thumbnails in folders that are not indexed')
    
      17provides=('wingdrive')
    
      18conflicts=('wingdrive' 'wingdrive-bin')
    
      19options=('!strip' '!debug')
    
      20_upstream_version=3.0.0
    
      21source=("WingDrive-3.0.0-x86_64.AppImage::https://github.com/bernardopg/wingdrive/releases/download/v${_upstream_version}/WingDrive-3.0.0-x86_64.AppImage"
    
      22        "LICENSE::https://github.com/bernardopg/wingdrive/releases/download/v${_upstream_version}/LICENSE")
    
      23sha256sums=('e09fe04ae2e8f1d7de9da2abbb2842c8525002e51e8a619be4942a37f3f9f9d1' '57b9dfbad7aaae518f06685835124ca850c722aceef664feaf6a05144b0e7ae8')
    
      24
    
      25# The AppImage carries an Ubuntu GTK/WebKit stack. Loading it next to Arch's
    
      26# libraries breaks host tools (gdbus) and crashes WebKit on exit, so only the
    
      27# FFmpeg build the daemon links against is kept; everything else comes from
    
      28# the system.
    
      29_bundled_libs='libavcodec.so.* libavfilter.so.* libavformat.so.* libavutil.so.* libpostproc.so.* libswresample.so.* libswscale.so.*'
    
      30
    
      31prepare() {
    
      32  chmod +x "WingDrive-3.0.0-x86_64.AppImage"
    
      33  "./WingDrive-3.0.0-x86_64.AppImage" --appimage-extract > /dev/null
    
      34  find squashfs-root -type d -exec chmod 755 {} +
    
      35}
    
      36
    
      37package() {
    
      38  local app="$pkgdir/opt/wingdrive"
    
      39  install -Dm755 squashfs-root/usr/bin/WingDrive "$app/usr/bin/WingDrive"
    
      40  install -Dm755 squashfs-root/usr/bin/wing-daemon "$app/usr/bin/wing-daemon"
    
      41  install -Dm755 squashfs-root/usr/bin/wing "$app/usr/bin/wing"
    
      42  install -d "$app/usr/lib"
    
      43  cp -a squashfs-root/usr/lib/WingDrive "$app/usr/lib/"
    
      44  (cd squashfs-root/usr/lib && cp -a $_bundled_libs "$app/usr/lib/")
    
      45
    
      46  local missing
    
      47  missing="$(ldd "$app/usr/bin/WingDrive" "$app/usr/bin/wing-daemon" "$app/usr/bin/wing" "$app"/usr/lib/*.so.* | grep 'not found' | sort -u || true)"
    
      48  if [[ -n "$missing" ]]; then
    
      49    printf 'Unresolved libraries:
    
      50%s
    
      51' "$missing" >&2
    
      52    return 1
    
      53  fi
    
      54
    
      55  install -d "$pkgdir/usr/bin"
    
      56  ln -s /opt/wingdrive/usr/bin/WingDrive "$pkgdir/usr/bin/wingdrive"
    
      57  # The CLI finds wing-daemon next to its resolved path, so a symlink works.
    
      58  ln -s /opt/wingdrive/usr/bin/wing "$pkgdir/usr/bin/wing"
    
      59  install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/wingdrive.desktop" <<'DESKTOP'
    
      60[Desktop Entry]
    
      61Type=Application
    
      62Name=WingDrive
    
      63GenericName=File Manager
    
      64Comment=Browse, organize and sync your files
    
      65Exec=wingdrive %U
    
      66TryExec=wingdrive
    
      67Icon=WingDrive
    
      68Terminal=false
    
      69StartupWMClass=WingDrive
    
      70Categories=System;FileTools;FileManager;
    
      71Keywords=files;folders;file manager;explorer;browser;
    
      72MimeType=inode/directory;application/x-wingdrive-memory;
    
      73X-GNOME-UsesNotifications=true
    
      74DESKTOP
    
      75  # No D-Bus activation file for org.freedesktop.FileManager1: the name
    
      76  # belongs to the user's default file manager. WingDrive claims it at runtime
    
      77  # only when it is the default for inode/directory (filemanager1.rs).
    
      78  if [[ -d squashfs-root/usr/share/icons ]]; then
    
      79    install -d "$pkgdir/usr/share/icons"
    
      80    cp -a squashfs-root/usr/share/icons/. "$pkgdir/usr/share/icons/"
    
      81  fi
    
      82  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      83  install -Dm644 squashfs-root/usr/lib/WingDrive/NOTICE "$pkgdir/usr/share/licenses/$pkgname/NOTICE"
    
      84  install -Dm644 squashfs-root/usr/lib/WingDrive/CREDITS.md "$pkgdir/usr/share/licenses/$pkgname/CREDITS.md"
    
      85  cp -a squashfs-root/usr/lib/WingDrive/licenses/. "$pkgdir/usr/share/licenses/$pkgname/"
    
      86}
    
      87

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-05 20:10:15	Low	2