wordnet-common

LOW

maintainer envolution 138 votes base wordnet scanned 2026-09-17 00:27:14.276658

View on AUR

Why flagged

The package downloads source files from Debian's official repository and Princeton's official WordNet site; all are legitimate project sources, and the build process applies standard patches and installs data and binaries normally, posing no inherent risk.

Triggered rules

Low AI review llm_review

An AI model (qwen/qwen3-235b-a22b-07-25) reviewed this and agrees it is LOW (confidence 95%): The package downloads source files from Debian's official repository and Princeton's official WordNet site; all are legitimate project sources, and the build process applies standard patches and installs data and binaries normally, posing no inherent risk.

1 higher static finding superseded - not the current verdict (shown for transparency)

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:23 "https://wordnetcode.princeton.edu/wn${pkgver}.dict.tar.gz"

PKGBUILD

1 offending line(s) highlighted

      1# Maintainer: envolution
    
      2# Contributor: Steven Allen <steven {at} stebalien {dot} com>
    
      3# Contributor: Reverie <reverie@takhis.net>
    
      4# shellcheck shell=bash disable=SC2034,SC2154
    
      5
    
      6pkgbase=wordnet
    
      7pkgname=(
    
      8  wordnet-common 
    
      9  wordnet-progs
    
      10  wordnet-dictd
    
      11)
    
      12pkgver=3.1
    
      13_srcver=3.0
    
      14pkgrel=16
    
      15arch=('i686' 'x86_64')
    
      16url="https://wordnet.princeton.edu/"
    
      17license=('GPL-2.0-only' 'LicenseRef-custom')
    
      18depends=(glibc python tcl tk ghostscript dictd) # dictd needed for dictzip command during build
    
      19source=(
    
      20  #"https://wordnetcode.princeton.edu/${_srcver}/WordNet-${_srcver}.tar.bz2"
    
      21  "http://deb.debian.org/debian/pool/main/w/wordnet/wordnet_${_srcver}-39.debian.tar.xz"
    
      22  "http://deb.debian.org/debian/pool/main/w/wordnet/wordnet_${_srcver}.orig.tar.gz"
    
      23  "https://wordnetcode.princeton.edu/wn${pkgver}.dict.tar.gz"
    
      24  wordnet.desktop
    
      25  wordnet.png
    
      26  wordnet-dictd.install)
    
      27sha256sums=('0e3001b38c6f77aaa276deff6276c9bbcb31dd17f32a9d2ee30e806bb4315c6e'
    
      28            '73572005ef8eb15be48ea1010d18082b80bfbf8684b78ce64bc3abf11db1f95f'
    
      29            '3f7d8be8ef6ecc7167d39b10d66954ec734280b5bdcd57f7d9eafe429d11c22a'
    
      30            '10a4011b3d9705b2b0a1f496b33d926d4be21439c63f039b871d93f2d143ed0c'
    
      31            '9ab9f761a3fabd278fd05d755fec8a403874f899d7e40347f1da48bf93a67e97'
    
      32            '6b6f7a11e781635e015da79cb8828d691073b6ae28f9b08c2065f3f3bd7a9f5f')
    
      33
    
      34prepare() {
    
      35  find . -type d -exec chmod 755 {} + && find . -type f -exec chmod 644 {} +
    
      36  mapfile -t _patch_series <debian/patches/series
    
      37  cd "$srcdir/WordNet-$_srcver"
    
      38  for _patch in "${_patch_series[@]}"; do
    
      39    patch -Np1 -i "../debian/patches/$_patch"
    
      40  done
    
      41  sed -i '/dictzip -n wn.dict/s/ -n//' contrib/wordnet_structures/Makefile*
    
      42
    
      43  #retain makefile(s) and use 3.1 (db)files
    
      44  find dict/ -type f ! -name 'Makefile*' -delete
    
      45  cp -a $srcdir/dict/. dict/ #upgrade to 3.1
    
      46  #3.1 expects frames.vrb rather than verb.FramesText
    
      47  mv -f dict/dbfiles/verb.Framestext dict/frames.vrb
    
      48  #point to 3.1 grind log file
    
      49  sed -i 's/log\.grind\.3\.0/log.grind.3.1/g' dict/Makefile.in
    
      50
    
      51  autoconf -fvi
    
      52}
    
      53
    
      54build() {
    
      55  cd "$srcdir/WordNet-$_srcver"
    
      56  sed 's:/usr/lib/wordnet/wishwn:/usr/bin/wishwn:g' -i src/wnb
    
      57  ./configure --prefix=/usr --mandir=/usr/share/man \
    
      58    CFLAGS="${CFLAGS} -std=gnu89 -fPIC -DUSE_INTERP_RESULT -Wno-error=format-security" \
    
      59    CXXFLAGS="${CXXFLAGS} -fPIC"
    
      60  make
    
      61}
    
      62
    
      63package_wordnet-dictd() {
    
      64  pkgdesc="Wordnet dictd files"
    
      65  arch=(any)
    
      66  provides=(dict-wn)
    
      67  conflicts=(dict-wn)
    
      68  license=('GPL-2.0-only' 'LicenseRef-custom')
    
      69  install=${pkgname}.install
    
      70  cd "${srcdir}/WordNet-${_srcver}"
    
      71  install -Dm644 contrib/wordnet_structures/wn.{dict.dz,index} -t "${pkgdir}"/usr/share/dictd/
    
      72  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
    
      73  install -D -m644 contrib/wordnet_structures/COPYING \
    
      74    "${pkgdir}/usr/share/licenses/$pkgname/contrib-COPYING"
    
      75  
    
      76}
    
      77package_wordnet-common() {
    
      78  depends+=(wordnet-progs wordnet-dictd)
    
      79  pkgdesc="An Electronic Lexical Database from Princeton University"
    
      80  license=('LicenseRef-custom')
    
      81  arch=(any)
    
      82
    
      83  cd "${srcdir}/WordNet-${_srcver}"
    
      84  make DESTDIR="$pkgdir" install
    
      85  # Replace dictionary files
    
      86  cp -ar "${pkgdir}/usr/dict/"* "${pkgdir}/usr/share/wordnet/"
    
      87  cp -an "$srcdir/dict/"* "$pkgdir/usr/share/wordnet/" #add 3.1 dict files
    
      88  rm -rf "${pkgdir}/usr/dict" #clean this default directory
    
      89  rm -rf "${pkgdir}/usr/"{lib,include,bin,dict}
    
      90  rm -rf "${pkgdir}/usr/share/man"
    
      91  rm -rf "${pkgdir}/usr/share/dictd" #moved to wordnet-dictd
    
      92  ln -s /usr/share/wordnet "${pkgdir}/usr/share/wordnet/dict" #support some old scripts
    
      93  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
    
      94}
    
      95package_wordnet-progs() {
    
      96  arch=(i686 x86_64)
    
      97  depends=(tcl tk glibc)
    
      98  pkgdesc="An Electronic Lexical Database from Princeton University (CLI and GUI tools)"
    
      99  license=('LicenseRef-custom')
    
      100
    
      101  cd "${srcdir}/WordNet-${_srcver}"
    
      102  make DESTDIR="$pkgdir" install
    
      103  rm -rf "${pkgdir}/usr/dict"
    
      104  rm -rf "${pkgdir}/usr/share/dictd"
    
      105  rm -rf "${pkgdir}/usr/share/wordnet/"*
    
      106
    
      107  mv "${pkgdir}/usr/lib/wnres" "${pkgdir}/usr/share/wordnet/wnres"
    
      108
    
      109  install -D -m644 "${srcdir}/wordnet.desktop" "${pkgdir}/usr/share/applications/wordnet.desktop"
    
      110  install -D -m644 "${srcdir}/wordnet.png" "${pkgdir}/usr/share/pixmaps/wordnet.png"
    
      111
    
      112  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/COPYING"
    
      113}
    
      114# vim:set ts=2 sw=2 et:
    
      115

Scan history

Scanned at (UTC)	Severity	Rules
2026-09-17 00:27:14	Low	2
2026-09-16 00:03:17	Low	2
2026-09-15 00:25:31	Low	2
2026-09-14 00:27:57	Low	2
2026-09-13 00:19:54	Low	2
2026-09-12 00:25:17	Low	2
2026-09-11 00:19:22	Low	2
2026-09-10 00:22:44	Low	2
2026-09-09 00:04:09	Low	2
2026-09-08 00:18:08	Low	2
2026-09-07 00:30:15	Low	2
2026-09-06 00:17:06	Low	2
2026-09-05 00:16:27	Low	2
2026-09-04 00:03:13	Low	2
2026-09-03 00:15:47	Low	2
2026-09-02 00:02:31	Low	2
2026-09-01 00:11:19	Low	2
2026-08-31 00:19:57	Low	2
2026-08-30 00:04:14	Low	2
2026-08-29 00:29:17	Low	2