xerotty-git

LOW

maintainer LXXero 0 votes scanned 2026-10-18 17:22:42.773931

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: xero <xero@xeron.cc>
    
      2pkgname=xerotty-git
    
      3_pkgname=xerotty
    
      4pkgver=r521.62baf4c
    
      5pkgrel=1
    
      6pkgdesc="Customizable terminal emulator in Go (SDL3 + Dear ImGui): multi-window, headless daemon mode, SSH-backed remote sessions, MCP server"
    
      7arch=('x86_64' 'aarch64')
    
      8url="https://github.com/LXXero/xerotty"
    
      9license=('GPL-3.0-or-later')
    
      10depends=('sdl3' 'fontconfig' 'freetype2' 'libglvnd' 'gcc-libs' 'glibc')
    
      11makedepends=('go' 'git')
    
      12provides=('xerotty')
    
      13conflicts=('xerotty')
    
      14# cimgui-go's C wrapper redeclares the Dear ImGui structs, which LTO
    
      15# reports as One Definition Rule violations (-Wodr); build without LTO.
    
      16options=('!lto')
    
      17source=("git+https://github.com/LXXero/xerotty.git"
    
      18        'xerotty.desktop')
    
      19sha256sums=('SKIP'
    
      20            '25bfb5491cbe34f7a1ab466be75caa80238b6e91f17eeba1f9de76c6c8c948df')
    
      21
    
      22pkgver() {
    
      23  cd "$_pkgname"
    
      24  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    
      25}
    
      26
    
      27build() {
    
      28  cd "$_pkgname"
    
      29  # build.sh runs `go generate` (tinylib/msgp codegen) before linking and
    
      30  # installs the msgp binary into $GOPATH/bin on first use, so keep GOPATH
    
      31  # inside srcdir and put its bin on PATH. -modcacherw lets makepkg delete
    
      32  # the module cache afterwards.
    
      33  export GOPATH="$srcdir/go"
    
      34  export PATH="$GOPATH/bin:$PATH"
    
      35  export CGO_CPPFLAGS="${CPPFLAGS}"
    
      36  export CGO_CFLAGS="${CFLAGS}"
    
      37  export CGO_CXXFLAGS="${CXXFLAGS}"
    
      38  export CGO_LDFLAGS="${LDFLAGS}"
    
      39  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    
      40  ./build.sh
    
      41}
    
      42
    
      43package() {
    
      44  cd "$_pkgname"
    
      45  install -Dm755 xerotty "$pkgdir/usr/bin/xerotty"
    
      46  # The binary finds these through $XDG_DATA_DIRS/xerotty/themes
    
      47  # (internal/themes.SearchDirs); ~/.config/xerotty/themes still wins.
    
      48  install -d "$pkgdir/usr/share/xerotty"
    
      49  cp -r themes "$pkgdir/usr/share/xerotty/themes"
    
      50  install -Dm644 icon/xerotty.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/xerotty.svg"
    
      51  install -Dm644 icon/xerotty-256.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/xerotty.png"
    
      52  install -Dm644 "$srcdir/xerotty.desktop" "$pkgdir/usr/share/applications/xerotty.desktop"
    
      53  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    
      54}
    
      55

Scan history

Scanned at (UTC)	Severity	Rules
2026-10-18 17:22:42	Low	1