xviewer-minimal

LOW

maintainer sfs 0 votes scanned 2026-11-03 12:04:35.126831

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# Maintainer: sfs sfslinux@gmail.com
    
      2
    
      3pkgname=xviewer-minimal
    
      4pkgver=2.6.2
    
      5pkgrel=2
    
      6pkgdesc='GTK3 image viewer with printing, without plugins or Cinnamon integration'
    
      7arch=('x86_64')
    
      8url='https://github.com/linuxmint/xviewer'
    
      9license=('GPL-2.0-or-later')
    
      10depends=(
    
      11  'at-spi2-core' 'cairo' 'dconf' 'gdk-pixbuf2'
    
      12  'glib2' 'glibc' 'gsettings-desktop-schemas' 'gtk3' 'hicolor-icon-theme'
    
      13  'zlib'
    
      14)
    
      15makedepends=('glib2-devel' 'gnome-common' 'libxml2')
    
      16optdepends=('cups: local print server, not required for PDF or a remote CUPS server')
    
      17provides=("xviewer=$pkgver")
    
      18conflicts=('xviewer')
    
      19source=("xviewer-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz"
    
      20        '0001-remove-plugins-and-introspection.patch'
    
      21        '0002-replace-cinnamon-desktop.patch')
    
      22sha256sums=('2bbe97181be7bbb9a163224640b9ba97377f8ac7850bd7f553d7737bd9207938'
    
      23            '2c87a896846a09215bfd2c09ef42b0d252f348bce37ac02c0c8c3795d7a42ca9'
    
      24            '91d50c548b3a15dba37564d5863c28f0a68541eba9e00842312b8067f1ea13d7')
    
      25options=('!debug')
    
      26
    
      27prepare() {
    
      28  cd "xviewer-$pkgver"
    
      29  patch -Np1 -i "$srcdir/0001-remove-plugins-and-introspection.patch"
    
      30  patch -Np1 -i "$srcdir/0002-replace-cinnamon-desktop.patch"
    
      31  # The installed-test macro is absent from the upstream release archive.
    
      32  sed -i '/^BEHAVE_INSTALLED_TESTS$/d' configure.ac
    
      33  mkdir -p m4
    
      34  gtkdocize --copy
    
      35  intltoolize --force --copy
    
      36  autoreconf -fi
    
      37}
    
      38
    
      39build() {
    
      40  cd "xviewer-$pkgver"
    
      41  # GCC 14+ rejects old GTK/GObject subclass pointer assignments.
    
      42  CFLAGS+=' -Wno-error=incompatible-pointer-types'
    
      43  ./configure \
    
      44    --prefix=/usr \
    
      45    --libdir=/usr/lib \
    
      46    --disable-static \
    
      47    --disable-gtk-doc \
    
      48    --without-libexif \
    
      49    --without-xmp \
    
      50    --without-cms \
    
      51    --without-librsvg \
    
      52    --without-libjpeg
    
      53  make
    
      54}
    
      55
    
      56package() {
    
      57  cd "xviewer-$pkgver"
    
      58  make DESTDIR="$pkgdir" install
    
      59}
    
      60

Scan history

Scanned at (UTC)	Severity	Rules
2026-11-03 12:04:35	Low	1