zulu-21-bin

MEDIUM

maintainer xiaoranya 6 votes scanned 2026-08-22 05:16:50.653524

View on AUR

Why flagged

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

Triggered rules

Medium source=() URL on a non-standard host source_untrusted_domain

One or more source=() URLs point to a host outside the trusted allowlist (github.com, gitlab.com, codeberg.org, pypi.org, …).

PKGBUILD:25 source_aarch64=("https://cdn.azul.com/zulu/bin/zulu${_zulu_build}-jdk${pkgver}-linux_aarch64.tar.gz")

PKGBUILD

1 offending line(s) highlighted

      1_java_ver=21
    
      2_jdkname="zulu-${_java_ver}"
    
      3_zulu_build="${_java_ver}.50.19-ca"
    
      4pkgname="${_jdkname}-bin"
    
      5pkgver="${_java_ver}.0.11"
    
      6pkgrel=1
    
      7pkgdesc='Azul Zulu builds of OpenJDK are open source, TCK-tested and certified builds of OpenJDK.'
    
      8arch=('aarch64' 'x86_64')
    
      9url='https://www.azul.com/downloads/'
    
      10license=('custom')
    
      11depends=(
    
      12  'java-environment-common>=3'
    
      13  'java-runtime-common>=3'
    
      14  'ca-certificates-utils'
    
      15)
    
      16provides=(
    
      17  "java-environment=$_java_ver"
    
      18  "java-environment-openjdk=$_java_ver"
    
      19  "java-runtime-headless=$_java_ver"
    
      20  "java-runtime-headless-openjdk=$_java_ver"
    
      21  "java-runtime=$_java_ver"
    
      22  "java-runtime-openjdk=$_java_ver"
    
      23)
    
      24install="$pkgname.install"
    
      25source_aarch64=("https://cdn.azul.com/zulu/bin/zulu${_zulu_build}-jdk${pkgver}-linux_aarch64.tar.gz")
    
      26source_x86_64=("https://cdn.azul.com/zulu/bin/zulu${_zulu_build}-jdk${pkgver}-linux_x64.tar.gz")
    
      27sha256sums_aarch64=('cd4be5eaed50d2b81485dfe260e2fab7e2c90a854bf11b7bfb4eeb6936757c4a')
    
      28sha256sums_x86_64=('bc5e3383431cb7f1dce8c262dd474501ee9bd7569f1c59a8b6fe5c1589aa4a58')
    
      29
    
      30_jvmdir="/usr/lib/jvm/${_jdkname}"
    
      31
    
      32package() {
    
      33  if [ "${CARCH}" = "aarch64" ]; then
    
      34    cd "$srcdir/zulu${_zulu_build}-jdk${pkgver}-linux_aarch64"
    
      35  else
    
      36    cd "$srcdir/zulu${_zulu_build}-jdk${pkgver}-linux_x64"
    
      37  fi
    
      38
    
      39  install -dm 755 "${pkgdir}/${_jvmdir}"
    
      40  cp -a . "${pkgdir}/${_jvmdir}/"
    
      41
    
      42  # based on java-openjdk package_jdk-openjdk
    
      43  # https://github.com/archlinux/svntogit-packages/blob/3f6aa8ddd98f728a9b0701288a933d16f0e8bbaf/trunk/PKGBUILD
    
      44
    
      45  # Conf
    
      46  install -dm 755 "${pkgdir}/etc"
    
      47  cp -r conf "${pkgdir}/etc/${_jdkname}"
    
      48  rm -r "${pkgdir}/${_jvmdir}/conf"
    
      49  ln -s "/etc/${_jdkname}" "${pkgdir}/${_jvmdir}/conf"
    
      50
    
      51  # Legal
    
      52  install -dm 755 "${pkgdir}/usr/share/licenses"
    
      53  cp -r legal "${pkgdir}/usr/share/licenses/${_jdkname}"
    
      54  rm -r "${pkgdir}/${_jvmdir}/legal"
    
      55  ln -s "/usr/share/licenses/${_jdkname}" "${pkgdir}/${_jvmdir}/legal"
    
      56
    
      57  # Man pages
    
      58  for f in bin/*; do
    
      59    f=$(basename "${f}")
    
      60    _man=man/man1/"${f}.1"
    
      61    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-${_jdkname}.1"
    
      62  done
    
      63  rm -r "${pkgdir}/${_jvmdir}/man"
    
      64  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"
    
      65
    
      66  # Link JKS keystore from ca-certificates-utils
    
      67  rm -f "${pkgdir}/${_jvmdir}/lib/security/cacerts"
    
      68  ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}/${_jvmdir}/lib/security/cacerts"
    
      69}
    
      70

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-22 05:16:50	Medium	1
2026-06-19 19:07:35	Clean	2
2026-06-19 18:54:17	Clean	2
2026-06-18 16:11:54	Medium	1