zz-beta-bin

LOW

maintainer demfabris 0 votes scanned 2026-08-27 15:32:51.856305

View on AUR

Why flagged

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

Triggered rules

Low Few votes, recently uploaded zero_votes_recent

Uploaded within the last 14 days with 2 or fewer community votes — little peer review so far.

PKGBUILD

      1# The zz-bin package published to aur.archlinux.org/packages/zz-bin, and the
    
      2# zz-beta-bin package prereleases publish to. This file is the template: the
    
      3# release workflow fills in the name, version, and checksums with
    
      4# scripts/render-aur.sh and pushes the result to the AUR, so edit this copy.
    
      5# packaging/arch/PKGBUILD is the local-development variant that packages a
    
      6# bundle built in-tree; keep the two in sync.
    
      7#
    
      8# The name carries the -bin suffix because this repackages the released Linux
    
      9# bundle rather than compiling one, and because plain `zz` on the AUR belongs
    
      10# to an unrelated project.
    
      11
    
      12pkgname=zz-beta-bin
    
      13# The release tag's version; pkgver cannot carry a prerelease hyphen.
    
      14_version=0.3.0-beta.2
    
      15pkgver=0.3.0beta.2
    
      16pkgrel=1
    
      17pkgdesc='Terminal, browser, and agent workspace'
    
      18arch=('x86_64' 'aarch64')
    
      19url='https://github.com/demfabris/zz'
    
      20license=('MIT OR Apache-2.0')
    
      21depends=(
    
      22    'alsa-lib'
    
      23    'at-spi2-core'
    
      24    'cairo'
    
      25    'dbus'
    
      26    'expat'
    
      27    'fontconfig'
    
      28    'glib2'
    
      29    'glibc'
    
      30    'hicolor-icon-theme'
    
      31    'libcups'
    
      32    'libgcc'
    
      33    'libx11'
    
      34    'libxcb'
    
      35    'libxcomposite'
    
      36    'libxdamage'
    
      37    'libxext'
    
      38    'libxfixes'
    
      39    'libxkbcommon'
    
      40    'libxkbcommon-x11'
    
      41    'libxrandr'
    
      42    'mesa'
    
      43    'nspr'
    
      44    'nss'
    
      45    'pango'
    
      46    'systemd-libs'
    
      47    'wayland'
    
      48)
    
      49optdepends=('org.freedesktop.secrets: import encrypted Chrome cookies')
    
      50# /usr/bin/zz and /usr/lib/zz can only have one owner.
    
      51provides=('zz')
    
      52conflicts=('zz' 'zz-bin')
    
      53# The bundle ships prebuilt and carries a full Chromium; stripping libcef.so
    
      54# would chew minutes to save nothing.
    
      55options=('!debug' '!strip')
    
      56source_x86_64=("$url/releases/download/v$_version/zz-$_version-linux-x86_64.tar.gz")
    
      57source_aarch64=("$url/releases/download/v$_version/zz-$_version-linux-aarch64.tar.gz")
    
      58sha256sums_x86_64=('b82eb2804103b6d341bd0fdd24640ef0d4ac1ef0e3e5177d74e153d48d3d0c4c')
    
      59sha256sums_aarch64=('ca2207a4f3425d8897cf3ebb471a4cbcb51adcd54af74ec7389bc65aa1fd6e53')
    
      60
    
      61package() {
    
      62    install -d "$pkgdir/usr"
    
      63    cp -a --no-preserve=ownership "$srcdir/zz-$_version-linux-$CARCH/usr/." "$pkgdir/usr/"
    
      64    chmod 0755 "$pkgdir/usr/lib/zz/zz" "$pkgdir/usr/lib/zz/cli" "$pkgdir/usr/lib/zz/chrome-sandbox"
    
      65    # The tarball ships its licenses under the app name.
    
      66    ln -s zz "$pkgdir/usr/share/licenses/$pkgname"
    
      67}
    
      68

Scan history

Scanned at (UTC)	Severity	Rules
2026-08-27 15:32:51	Low	1